0

我有一条atom规则，它首先尝试将所有内容解析为数字或带引号的字符串，如果失败，则将其视为字符串。

一切都很好解析，除了一个特殊的情况是这个非常具体的字符串：

DUD 123abc

无法解析Expected " ", "." or [0-9] but "a" found.错误。

我的期望：它应该成功解析并将字符串“123abc”作为字符串原子返回。您可以在下面的语法内容中看到我的几个不成功的尝试被注释掉了。

任何帮助/提示/指针/建议表示赞赏！

你可以在网上的 PEG.js 版本上试试语法。我正在使用节点 v0.8.23 和 pegjs 0.7.0

正确解析的数字：

  • `123
  • `0
  • `0。
  • `1。
  • `.23
  • `0.23
  • `1.23
  • `0.000
  • . <--- 作为字符串，不是数字，也不是错误

我想123abc被解析为字符串，这可能吗？

这是我的整个语法文件：

start = lines:line+ { return lines; }

// --------------------- LINE STRUCTURE
line = command:command eol { return command; }

command = action:atom args:(sep atom)*
{
  var i = 0, len = 0;

  for (var i = 0, len = args.length; i < len; i++) {
    // discard parsed separator tokens
    args[i] = args[i][1];
  }

  return [action, args];
}

sep = ' '+
eol = "\r" / "\n" / "\r\n"

atom = num:number { return num; }
     / str:string_quoted { return str; }
     / str:string { return str; }

// --------------------- COMMANDS

// TODO:

// --------------------- STRINGS
string = chars:([^" \r\n]+) { return chars.join(''); }

string_quoted = '"' chars:quoted_chars* '"' { return chars.join(''); }
quoted_chars = '\\"' { return '"'; }
             / char:[^"\r\n] { return char; }

// --------------------- NUMBERS
number = integral:('0' / [1-9][0-9]*) fraction:("." [0-9]*)?
{
  if (fraction && fraction.length) {
    fraction = fraction[0] + fraction[1].join('');
  } else {
    fraction = '';
  }

  integral = integral instanceof Array ?
    integral[0] + integral[1].join('') :
    '0';

  return parseFloat(integral + fraction);
}
        / ("." / "0.") fraction:[0-9]+
{
  return parseFloat("0." + fraction.join(''));
}

/*
float = integral:integer? fraction:fraction { return integral + fraction; }

fraction = '.' digits:[0-9]* { return parseFloat('0.' + digits.join('')); }

integer = digits:('0' / [1-9][0-9]*)
{
  if (digits === '0') return 0;
  return parseInt(digits[0] + digits[1].join(''), 10);
}

*/
4

2 回答 2

3

通过添加规则!([0-9\.]+[^0-9\.])的前瞻来解决这个问题number。

我知道atom规则会匹配，所以它的有效作用是让number规则更快地失败。希望这可以帮助将来有歧义的人。

所以现在的数字规则变成了：

number = !([0-9\.]+[^0-9\.]) integral:('0' / [1-9][0-9]*) fraction:("." [0-9]*)?

于 2013-04-18T12:03:26.520 回答
1

我认为检查字符尾随number是数字分隔符（不是字母数字）也可以，而且更便宜。

number = integral:('0' / [1-9][0-9]*) fraction:("." [0-9]*)? !([0-9A-Za-z])
于 2013-04-19T12:47:13.063 回答