3

我正在尝试转换 XML 文档。首先，我定义了一个全局变量：

 <xsl:variable name="foo"><xsl:value-of select="bar"/></xsl:variable>

现在我正在转换的 XML 有可能已经<bar>some data</bar>定义了。也有可能没有定义。

一旦我在下面声明了全局变量，如果它被定义，我将尝试输出以下内容：

<foo>DEFINED</foo>

如果没有定义：

<foo>NOT DEFINED</foo>

我在用<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

解决这个问题的最佳方法是什么？

4

3 回答 3

7

由于您使用的是 XSLT 1.0，因此您可以使用它string()来进行测试。

这是一个示例样式表：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/*">
        <xsl:variable name="foo" select="bar"/>
        <results>
            <xsl:choose>
                <xsl:when test="string($foo)">
                    <foo>DEFINED</foo>
                </xsl:when>
                <xsl:otherwise>
                    <foo>NOT DEFINED</foo>
                </xsl:otherwise>
            </xsl:choose>           
        </results>
    </xsl:template>

</xsl:stylesheet>

请注意，空白已折叠，因此<bar> </bar>将返回 false。此外，string()在直接测试元素而不是变量时也可以使用。

以下是一些输入/输出示例：

输入

<test>
    <bar/>
</test>

或者

<test>
    <bar></bar>
</test>

或者

<test>
    <bar>    </bar>
</test>

输出

<foo>NOT DEFINED</foo>

输入

<test>
    <bar>x</bar>
</test>

输出

<foo>DEFINED</foo>

如果您可以使用 XSLT 2.0，您可以将变量声明为 anxs:string并在 test ( test="$foo") 中使用变量名。

例子：

<xsl:stylesheet version="2.0" xmlns:xs="http://www.w3.org/2001/XMLSchema" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" exclude-result-prefixes="xs">
    <xsl:output indent="yes"/>
    <xsl:strip-space elements="*"/>

    <xsl:template match="/*">
        <xsl:variable name="foo" select="bar" as="xs:string"/>
        <results>
            <xsl:choose>
                <xsl:when test="$foo">
                    <foo>DEFINED</foo>
                </xsl:when>
                <xsl:otherwise>
                    <foo>NOT DEFINED</foo>
                </xsl:otherwise>
            </xsl:choose>           
        </results>
    </xsl:template>

</xsl:stylesheet>
于 2013-04-16T23:53:11.950 回答
0

我不确定这是否有效，但......

添加xmlns:fn="http://www.w3.org/2005/xpath-functions"到您的样式表。

<xsl:choose>
  <xsl:when test="fn:boolean(foo)">
    <foo>DEFINED</foo>
  </xsl:when>
  <xsl:otherwise>
    <foo>NOT DEFINED</foo>
  </xsl:otherwise>
</xsl:choose>

编辑：@JimGarrison 如果有效，这将按<bar/>定义处理<bar></bar>。

于 2013-04-16T22:29:09.530 回答
0

变量 foo 将包含您的 xml 包含 bar 的 xml 节点 bar（不仅是 bar 的内容的文本）。因此，“@indeterminately sequenced”的答案是正确的，您可以测试 foo 是否包含带有test="boolean($foo)". 但我更喜欢 'test="name($foo)". Or test="name($foo) = 'bar' 这会导致：

<xsl:variable name ="foo" select="*/bar" />

<xsl:template match="/">
    <results>
        <xsl:choose>
            <xsl:when test="name($foo)">
                <foo>DEFINED</foo>
            </xsl:when>
            <xsl:otherwise>
                <foo>NOT DEFINED</foo>
            </xsl:otherwise>
        </xsl:choose>
    </results>
</xsl:template>
于 2013-04-17T09:00:39.340 回答