0

我的示例 xml 如下所示： 我需要从 xml 中获取不同的状态。我在 vs 2010 编辑器中使用 xslt 1.0。

<?xml version="1.0" encoding="utf-8" ?>
<states>
  <node>
    <value>2</value>
    <state>DE</state>
  </node>
  <node>
    <value>1</value>
    <state>DE</state>
  </node>
  <node>
    <value>1</value>
    <state>NJ</state>
  </node>
  <node>
    <value>1</value>
    <state>NY</state>
  </node>

  <node>
    <value>1</value>
    <state>NY</state>
  </node>
</states>

我的 xslt 如下所示：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:msxsl="urn:schemas-microsoft-com:xslt" exclude-result-prefixes="msxsl"
   xmlns:user="urn:my-scripts">

  <xsl:output method="text" indent="yes"/>

  <xsl:key name="st" match="//states/node/state" use="." />

  <xsl:variable name="disst">
    <xsl:for-each select="//states/node[contains(value,1)]/state[generate-id()=generate-id(key('st',.)[1])]" >
      <xsl:choose>
        <xsl:when test="(position() != 1)">
          <xsl:value-of select="concat(', ',.)" disable-output-escaping="yes"/>
        </xsl:when>
        <xsl:otherwise>
          <xsl:value-of select="." disable-output-escaping="yes"/>
        </xsl:otherwise>
      </xsl:choose>

    </xsl:for-each>


  </xsl:variable>

    <xsl:template match="/" >
      <xsl:value-of disable-output-escaping="yes" select="$disst"/>

    </xsl:template>
</xsl:stylesheet>

输出：DE、NJ、NY

我上面的 xml 看起来很适合上面的测试 xml。

如果我将 xml 更改如下：

<?xml version="1.0" encoding="utf-8" ?>
<states>
  <node>
    <value>2</value>
    <state>DE</state>
  </node>
  <node>
    <value>1</value>
    <state>DE</state>
  </node>
  <node>
    <value>1</value>
    <state>NJ</state>
  </node>
  <node>
    <value>1</value>
    <state>NY</state>
  </node>

  <node>
    <value>1</value>
    <state>NY</state>
  </node>
</states>

它没有选择州DE。任何人都可以提出合适的解决方案。在此先感谢。我需要从 xml 中找出不同的状态。

4

1 回答 1

2

这里的问题是您在 Muenchian 分组 XPath 中使用了谓词：

[contains(value,1)]

这通常会使 Muenchian 分组无法找到所有可用的不同值。相反，您应该将谓词添加到键中：

<xsl:key name="st" match="//states/node[contains(value, 1)]/state" use="." />

或者，您可以在分组语句中应用谓词：

<xsl:apply-templates 
   select="//states/node
               /state[generate-id() =
                      generate-id(key('st',.)[contains(../value, 1)][1])]" />

完整的 XSLT（有一些改进）：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:user="urn:my-scripts">
  <xsl:output method="text" indent="yes"/>

  <xsl:key name="st" match="//states/node/state" use="." />
  <xsl:variable name="a" select="1" />

  <xsl:variable name="disst">
    <xsl:apply-templates
       select="//states/node
                   /state[generate-id() =
                          generate-id(key('st',.)[contains(../value, $a)][1])]" />
  </xsl:variable>

  <xsl:template match="state">
    <xsl:if test="position() > 1">
      <xsl:text>,</xsl:text>
    </xsl:if>
    <xsl:value-of select ="." disable-output-escaping="yes" />
  </xsl:template>

  <xsl:template match="/" >
    <xsl:value-of disable-output-escaping="yes" select="$disst"/>

  </xsl:template>
</xsl:stylesheet>

在示例 XML 上运行时的结果：

DE,NJ,NY
于 2013-04-04T19:35:11.953 回答