3

我正在 Flash Develop 中创建一个非常简单的全屏拖放游戏。除了在一个令人沮丧的情况下，它工作正常。

我将项目添加到舞台，向它们添加 MOUSE_DOWN 侦听器，并在听到该侦听器时开始拖动。然后我添加一个 MOUSE_UP 侦听器来确定何时停止拖动。同样，除非 mouseX = 0，否则这工作正常。当鼠标一直位于屏幕左侧并且我鼠标向上或向下时，不会触发任何侦听器。我还把它从全屏模式中取出，如果鼠标处于或低于 0，则不会触发鼠标事件。

世界上到底发生了什么？

    private function itemSelectedHandler(e:MouseEvent):void 
    {
        thisItem = GameItem(e.currentTarget);
        thisItem.startDrag();
        stage.addEventListener(MouseEvent.MOUSE_UP, itemUnselectedHandler, false, 0, true);
    }

    private function itemUnselectedHandler(e:MouseEvent):void 
    {
        stopDrag();
        stage.removeEventListener(MouseEvent.MOUSE_UP, itemUnselectedHandler);
        thisItem.removeEventListener(MouseEvent.MOUSE_DOWN, itemSelectedHandler);   
    }
4

1 回答 1

3

您在类上调用 stopDrag 而不是拖动的精灵。尝试以下操作：

package 
{
    public class Main extends Sprite 
    {

        private var _draggedSprite:Sprite = null;

        public function Main():void 
        {
            if (stage) init();
            else addEventListener(Event.ADDED_TO_STAGE, init);
        }

        private function init(e:Event = null):void 
        {
            removeEventListener(Event.ADDED_TO_STAGE, init);
            // entry point

            for (var i:int = 0; i < 10; i++) 
            {
                createBox();
            }
        }

        private function createBox():void
        {
            var sp:Sprite = new Sprite();
            sp.graphics.beginFill(0xff0000, 1);
            sp.graphics.drawRect(0, 0, 30, 30);
            sp.graphics.endFill();
            sp.addEventListener(MouseEvent.MOUSE_DOWN, onMouseDown);

            sp.x = Math.random() * (stage.stageWidth - 30);
            sp.y = Math.random() * (stage.stageHeight - 30);

            addChild(sp);
        }

        private function onMouseDown(e:MouseEvent):void 
        {
            var sp:Sprite = e.target as Sprite;
            sp.startDrag();
            _draggedSprite = sp;

            stage.addEventListener(MouseEvent.MOUSE_UP, onMouseUp);
        }

        private function onMouseUp(e:MouseEvent):void 
        {
            _draggedSprite.stopDrag();
            _draggedSprite = null;
            stage.removeEventListener(MouseEvent.MOUSE_UP, onMouseUp);
        }

    }

}

当 mouseX=0 在全屏模式下时，这对我有用。

于 2013-04-02T19:24:48.813 回答