4

在得到一些帮助后，理解了我试图编译代码的问题，在这个问题中（Trouble understand GHC 关于歧义的抱怨）Will Ness 建议我重新设计我的类型类以避免我不完全满意的解决方案。

有问题的类型类是这些：

class (Eq a, Show a) => Genome a where
    crossover       :: (Fractional b) => b -> a -> a -> IO (a, a)
    mutate          :: (Fractional b) => b -> a -> IO a
    develop         :: (Phenotype b)  => a -> b

class (Eq a, Show a) => Phenotype a where
    --In case of Coevolution where each phenotype needs to be compared to every other in the population
    fitness         :: [a] -> a -> Int 
    genome          :: (Genome b) => a -> b

我正在尝试在 Haskell 中创建一个可扩展的进化算法，它应该支持不同的Genomes和Phenotypes. 例如，一个Genome可能是一个位数组，另一个可能是一个整数列表，并且它Phenotypes也将不同于http://en.wikipedia.org/wiki/Colonel_Blotto中代表部队运动的双打列表，或者它可以代表一个ANN。

由于 aPhenotype是从 a 开发的，Genome因此使用的方法必须是完全可互换的，并且一个Genome类应该能够Phenotypes通过提供不同的开发方法来支持多个（这可以在代码中静态完成，而不必在运行时动态完成）。

在大多数情况下，使用这些类型类的代码应该完全不知道所使用的特定类型，这就是我提出上述问题的原因。

我想适应这些类型类的一些代码是：

-- |Full generational replacement selection protocol
fullGenerational :: (Phenotype b) =>
    (Int -> [b] -> IO [(b, b)]) -> --Selection mechanism
    Int -> --Elitism
    Int -> --The number of children to create
    Double -> --Crossover rate
    Double -> --Mutation rate
    [b] -> --Population to select from
    IO [b] --The new population created
fullGenerational selection e amount cross mute pop = do
    parents <- selection (amount - e) pop
    next <- breed parents cross mute
    return $ next ++ take e reverseSorted
            where reverseSorted = reverse $ sortBy (fit pop) pop

breed :: (Phenotype b, Genome a) => [(b, b)] -> Double -> Double -> IO [b]
breed parents cross mute = do
    children <- mapM (\ (dad, mom) -> crossover cross (genome dad) (genome mom)) parents
    let ch1 = map fst children ++ map snd children
    mutated <- mapM (mutate mute) ch1
    return $ map develop mutated

我知道必须更改此代码并且必须添加新的约束，但我想展示一些使用类型类的代码。例如，上面的全代替换不需要知道任何关于底层的信息Genome就可以正常运行；它只需要知道Phenotypes能生产Genome出它的那个，这样它就可以将它们一起繁殖并创造出新的孩子。的代码fullGenerational应该尽可能通用，这样一旦Phenotype设计了新的或创建了更好Genome的代码，就不需要更改。

如何更改上面的类型类以避免我在类型类歧义方面遇到的问题，同时在一般 EA 代码中保留我想要的属性（应该是可重用的）？

4

1 回答 1

7

“它只需要知道表型可以产生产生它的基因组”

这意味着表型实际上是两种类型的关系，另一种是用于产生给定表型的基因组类型：

{-# LANGUAGE MultiParamTypeClasses #-}
{-# LANGUAGE FunctionalDependencies #-}

import Data.List (sortBy)

class (Eq a, Show a) => Genome a where
    crossover       :: (Fractional b) => b -> a -> a -> IO (a, a)
    mutate          :: (Fractional b) => b -> a -> IO a
    develop         :: (Phenotype b a) => a -> b

class (Eq a, Show a, Genome b) => Phenotype a b | a -> b where
    --  In case of Coevolution where each phenotype needs to be compared to 
    --  every other in the population
    fitness         :: [a] -> a -> Int 
    genome          :: a -> b

breed :: (Phenotype b a, Genome a) => [(b, b)] -> Double -> Double -> IO [b]
breed parents cross mute = do
    children <- mapM (\(dad, mom)-> crossover cross (genome dad) (genome mom)) 
                     parents
    let ch1 = map fst children ++ map snd children
    mutated <- mapM (mutate mute) ch1
    return $ map develop mutated

-- |Full generational replacement selection protocol
fullGenerational :: (Phenotype b a, Genome a) =>
    (Int -> [b] -> IO [(b, b)]) -> --Selection mechanism
    Int -> --Elitism
    Int -> --The number of children to create
    Double -> --Crossover rate
    Double -> --Mutation rate
    [b] -> --Population to select from
    IO [b] --The new population created
fullGenerational selection e amount cross mute pop = do
    parents <- selection (amount - e) pop
    next <- breed parents cross mute
    return $ next ++ take e reverseSorted
            where reverseSorted = reverse $ sortBy (fit pop) pop

fit pop a b = LT   -- dummy function

这编译。每个表型都必须提供一个.genome

于 2013-04-02T17:12:20.150 回答