0

好的，所以我有一个Flash游戏，一个平台游戏。在这个游戏中你必须跳过尖峰。所以我创建了尖峰并将其转换为一个符号，一个电影剪辑。当它注册为一个电影剪辑时，它不是一个三角形（如尖刺），而是一个矩形。这意味着当玩家避开尖刺并跳跃时，如果他离得太近，他会死，但他没有击中尖刺，他会撞到周围的隐形矩形尖峰。无论如何要改变影片剪辑的形状，使其适合尖峰和尖峰。

4

4 回答 4

1

你可以使用hittest，这里是一个使用示例

http://www.foundation-flash.com/tutorials/as3hittesting/

于 2013-03-31T15:13:19.363 回答
0

您可以像这样使用BitmapDatawithhitTest来检查像素级碰撞。

（要测试代码，请在 Flash 舞台上放置两个符号，“rectClip”和“spike”。还要先测试它，让它们远离，然后再让它们触摸并测试它。）

（无论哪种方式，您都可以设置MouseMove或startDrag()实时检查。）

var rect:Rectangle = rectClip.getBounds(this);
var rectClipBmpData = new BitmapData(rect.width, rect.height, true, 0);
rectClipBmpData.draw(rectClip);

var spikeRect:Rectangle = spike.getBounds(this);
var spikeBmpData = new BitmapData(spikeRect.width, spikeRect.height, true, 0);
spikeBmpData.draw(spike);

if(rectClipBmpData.hitTest(new Point(rectClip.x, rectClip.y),
                                 255,
                                 spikeBmpData,
                                 new Point(spike.x,spike.y),
                                 255 ))
{
     trace("hit");
}else
{
     trace("No hit");
}

好运。

于 2013-03-31T20:02:17.120 回答
0

根据我处理相同类型问题的经验，你不能真正使用AS3 hitTestObjectMC 的特定形状（如果你遇到这个问题，我会想象你正在使用它）。它总是默认为占用影片剪辑本身空间的框。

因此，要回答您的问题，不，您不能更改 MC 的形状以使其仅尖峰，默认情况下hitTestObject使用 MC 周围的边界框。

解决这个问题的方法很少（很多人建议不要hitTestOjbect一般使用，因为它效率不高，而是编写自己的命中测试代码。我建议在网上寻找这样的例子，有很多）。

如果您不想处理这个问题，您的另一个选择是创建一个单独的一系列盒形 mc，它们充当您的边界框并且可以排列在数组中，然后运行一个循环来查看您的角色是否是击中任何一个。这样，您可以根据需要调整边界框大小。

但是如果你想使用hitTestObject，不幸的是你必须使用整个对象边界框。由于我不完全确定您将如何处理此问题的详细信息，因此我最好的建议是上网阅读 AS3 中命中检测的基础知识。

您的问题在于命中检测，不一定是电影剪辑。

于 2013-03-31T15:18:49.153 回答
0

对象之间的内部命中测试将检查对象的边界框，因此这对您不起作用。

如果您可以以某种方式将玩家代理用作一个点（最低点，例如他的脚中部或类似的东西），您可以使用spike.hitTestPoint(globalFootX, globalFootY, true);

如果这不起作用，您要么必须手动为项目创建 hittest-representation 并执行您自己的 hittest 逻辑。

另一种解决方案是将项目绘制到单独的精灵上，然后查看像素是否重叠。我知道我在一个旧的 AS2 项目中做到了这一点，其中不规则形状的 AI 机器人在一个不规则形状的世界中四处移动。

我将提供该代码以供参考，它可能可以转换为 AS3，或者至少您可以将其用作谷歌搜索的灵感，以便在 AS3 中找到该解决方案。

class messer_studios.utils.CollisionDetection {
    static public function checkForCollision(p_clip1:MovieClip, p_clip2:MovieClip, p_alphaTolerance:Number):Rectangle {     
        // set up default params:
        if (p_alphaTolerance == undefined) {
            p_alphaTolerance = 255;
        }

        // get bounds:   
        var bounds1:Object = p_clip1.getBounds(_root);
        var bounds2:Object = p_clip2.getBounds(_root);

        // rule out anything that we know can't collide:
        if (((bounds1.xMax < bounds2.xMin) || (bounds2.xMax < bounds1.xMin)) || ((bounds1.yMax < bounds2.yMin) || (bounds2.yMax < bounds1.yMin))) {
            return null;
        }
        //Debug.log("might collide");

        // determine test area boundaries:   
        var bounds:Object = {};
        bounds.xMin = Math.max(bounds1.xMin, bounds2.xMin);
        bounds.xMax = Math.min(bounds1.xMax, bounds2.xMax);
        bounds.yMin = Math.max(bounds1.yMin, bounds2.yMin);
        bounds.yMax = Math.min(bounds1.yMax, bounds2.yMax);

        // set up the image to use:
        var img:BitmapData = new BitmapData(bounds.xMax-bounds.xMin, bounds.yMax-bounds.yMin, false);

        // draw in the first image:
        var mat:Matrix = p_clip1.transform.concatenatedMatrix;
        mat.tx -= bounds.xMin;
        mat.ty -= bounds.yMin;
        img.draw(p_clip1, mat, new ColorTransform(1, 1, 1, 1, 255, -255, -255, p_alphaTolerance));

        // overlay the second image:
        mat = p_clip2.transform.concatenatedMatrix;
        mat.tx -= bounds.xMin;
        mat.ty -= bounds.yMin;
        img.draw(p_clip2, mat, new ColorTransform(1, 1, 1, 1, 255, 255, 255, p_alphaTolerance), "difference");

        // find the intersection:
        var intersection:Rectangle = img.getColorBoundsRect(0xFFFFFFFF, 0xFF00FFFF);
        // if there is no intersection, return null:
        if (intersection.width == 0) {
            return null;
        }

        // adjust the intersection to account for the bounds:   
        intersection.x += bounds.xMin;
        intersection.y += bounds.yMin;
        return intersection;
    };

    public static function hitTestShape(mc1:MovieClip, mc2:MovieClip, alphaTolerence:Number):Boolean {
        return checkForCollision(mc1, mc2, alphaTolerence) != null ? true : false;
    }
}
于 2013-03-31T15:40:00.930 回答