1

我是初学者。我编写了一个 perl 脚本，它执行以下操作

- 在当前日期之前在“/x01/abcd/abc_logs/abcd_Logs”下创建一个目录，如果尚未创建，格式为“YYYYMMDD”。即：如果脚本在“2013 年 1 月 1 日”运行，则将在上述路径下创建目录“20130101”。因此，每当需要检查日志时，始终查找当前日期的目录。

-检查日志文件是否已经在同一天早些时候下载，如果没有，日志将被下载到今天的目录。

我很难想出一个解决方案来在共享中没有文件时打印一条消息。这当然是当用户指定共享中不存在的 2 个或更多文件时。我知道发生这种情况是因为“sub get_LOGS”中有一个“die”语句。当我指定的所有文件都没有碰巧在共享中时，我似乎无法理解如何返回消息。

该脚本的用法如下

./abc_logs ....<文件(n)>

以下是脚本。

my $LOGS_LOCAL_PATH = "/x02/abc/abcba2/";
chomp $LOGS_LOCAL_PATH;
my $LOGS_REM_PATH = "/x01/INT/abc/vabc2/";
chomp $LOGS_REM_PATH;
my $TODAY = `date +%Y%m%d`;
chomp $TODAY;
my @GETLOOP = @ARGV;
    unless ($#ARGV >= 0) {
        print "\nUsage: gtp_logs.pl <file1> <file2> <file3>.....<file(n)>\n\n";
        exit;
    }
        system("clear");
    unless ( -d "$LOGS_LOCAL_PATH"."$TODAY") {
        print "Directory \"$TODAY\" doesn't exist. So creating the directory..!\n";
        print "OK..Done.....!\n\n";
        system("mkdir $LOGS_LOCAL_PATH/$TODAY");
        }
    else {
        print "Directory already exists. Logs will be downloaded to ==>     \"$LOGS_LOCAL_PATH$TODAY\".....!\n\n";
    }
    
               # if_DOWNLOADED($LOGS_LOCAL_PATH,$TODAY,@GETLOOP);
    
    chdir("$LOGS_LOCAL_PATH"."$TODAY") || die "cannot cd to  ($!)";
    foreach my $GETL (@GETLOOP) {
    my $is_downloaded = if_DOWNLOADED($LOGS_LOCAL_PATH,$TODAY,$GETL);
    if(!$is_downloaded)
    {
        get_LOGS("172.25.70.221","abc","abc2","/x01/INT/abc",$GETL);
        print "File \"$GETL\" downloaded to ==>          \"$LOGS_LOCAL_PATH$TODAY\"\n\n";
    }
    else
    {
        print "File \"$GETL\" has already been Downloaded to ==>          \"$LOGS_LOCAL_PATH$TODAY\"\n\n";
    }
    
    
    }
    

 sub get_LOGS {
    my $LOG_HOST  = shift;
    my $REM_USER  = shift;
    my $REM_PASSW = shift;
    my $REM_PATH  = shift;
    my $REM_FILE  = shift;
    
        print "Connecting to the sftp share! Please wait....!\n";
        my $sftp = Net::SFTP::Foreign->new($LOG_HOST, user => $REM_USER, password => $REM_PASSW);
        $sftp->setcwd($REM_PATH) or die "unable to change cwd: " . $sftp->error;
        print "OK. On the share! Downloading the file \"$REM_FILE\"...................!\n\n\n\n";
        $sftp->error and die "Problem connecting to the share...!!!! " . $sftp->error;
        $sftp->get($REM_FILE) or die "File does not seem to be present on the remote share. Please re-request..!!!" . $sftp->error;
        return $REM_FILE;
}
   
sub if_DOWNLOADED {
    my $DWD_FILE_PATH = shift;
    my $DWD_DIR       = shift;
    my $DWD_FILE      = shift;
    if (-e "$DWD_FILE_PATH/$DWD_DIR/$DWD_FILE")
    {
        return 1;
    }
    else
    {
        return 0;
    }
}

请问有人可以帮我找到解决这个问题的方法吗？请尝试使用相同的脚本并进行修改。

/V

4

1 回答 1

3

对您的代码的一些评论：

  • 使用 strict 和 warnings 以便及早发现大量错误。

  • 阅读一些关于风格的书（即 Damian Conway 的 Perl Best Practices）。但无论如何，在命名变量、子例程和所有内容以及它们的大小写时都要尽量保持一致。

  • 当您必须在多个地方使用某个计算值时，请尝试计算一次并将其保存在变量中。

  • 不要将子程序用于琐碎的事情。

  • 您不需要调用已定义且末尾chomp没有字符的变量。"\n"

  • 为每个文件传输打开一个新的 SFTP 连接是非常低效的。您可以在开始时只打开一个并将其用于所有传输。

现在，您的脚本的简化版本：

#!/usr/bin/perl

use strict;
use warnings;

my $host = "172.25.70.221";
my $user = "abc";
my $password = "abc1234321";

my $LOGS_LOCAL_PATH = "/x02/ABC/abc2";
my $LOGS_REM_PATH = "/x01/INT/abc/vim";
my $TODAY = `date +%Y%m%d`;
chomp $TODAY;
my $TODAY_LOCAL_PATH = "$LOGS_LOCAL_PATH/$TODAY";

my @files = @ARGV;
@files or die "\nUsage: gtp_logs.pl <file1> <file2> <file3>.....<file(n)>\n\n";

system("clear");

if ( -d $TODAY_LOCAL_PATH) {
    print "Directory already exists. Logs will be downloaded to ==>     \"$TODAY_LOCAL_PATH\".....!\n\n";
}
else {
    print "Directory \"$TODAY\" doesn't exist. So creating the directory..!\n";
    mkdir "$TODAY_LOCAL_PATH" or die "unable to create directory: $!\n";
    print "OK..Done.....!\n\n";
}

chdir $TODAY_LOCAL_PATH or die "cannot cd to  ($!)\n";

my $sftp =  Net::SFTP::Foreign->new($host, user => $user, password => $password);
$sftp->error
    and die "Problem connecting to the share...!!!! " . $sftp->error;

my $ok = 0;
my $failed = 0;
foreach my $file (@files) {
    if (-e "$TODAY_LOCAL_PATH/$file") {
        print "File \"$file\" has already been Downloaded to ==>          \"$TODAY_LOCAL_PATH\"\n";
    }
    else {
        if ($sftp->get("$LOGS_REM_PATH/$file")) {
            print "File \"$file\" downloaded to ==>          \"$TODAY_LOCAL_PATH\"\n";
            $ok++;
        }
        else {
            print "Unable to download file \"$file\" : " . $sftp->error . "\n";
            $failed++;
        }
    }
}

print "$ok files have been downloaded, $failed files failed!\n\n";
于 2013-03-21T09:16:30.250 回答