0

我已经为此工作了几个星期，我可以让它像它一样工作。它几乎就在那里，我想我只是缺少一些东西。我基本上不能让块和球之间的碰撞检测像我想让它们工作一样工作。

转储 SWF

球仍然有机会在几秒钟内犁出大量的块。我很想听听有类似问题的人的意见。

这是代码；

private function checkCollision():void
    {
        grdx = Math.floor((ball.x) / 28);
        grdy = Math.floor((ball.y) / 14);
        ngrdx = Math.floor((ball.x + dx) / 28);
        ngrdy = Math.floor((ball.y + dy) / 14);


        if (grdy <= level.length - 1 && ngrdy <= level.length - 1 && grdy >= 0 && ngrdy >= 0) 
        {   

            if(level[grdy][ngrdx] > 0) 
            {

                level[grdy][ngrdx] = 0;
                bnm = "Block_" + grdy + "_" + ngrdx;    
                if (this.getChildByName(bnm) != null)
                {

                    this.removeChild(this.getChildByName(bnm));
                    dx *= -1;   
                    totalBreaks++;

                    trace("Hit on X");
                    trace("Block: " + totalBreaks + " / " +  totalBlocks);
                }


            }
            else if(level[ngrdy][grdx] > 0) 
            {               

                bnm = "Block_" + ngrdy + "_" + grdx;
                level[ngrdy][grdx] = 0; 
                 if (this.getChildByName(bnm) != null)
                {

                    this.removeChild(this.getChildByName(bnm));
                    dy *= -1;
                    totalBreaks++;
                    trace("Hit on Y");
                    trace("Block: " + totalBreaks + " / " +  totalBlocks);
                }
            }
            if(level[ngrdy][ngrdx] > 0) 
            {               

                bnm = "Block_" + ngrdy + "_" + ngrdx;
                level[ngrdy][ngrdx] = 0;    
                if (this.getChildByName(bnm) != null)
                {

                    this.removeChild(this.getChildByName(bnm));
                    dy *= -1;
                    dx *= -1;
                    totalBreaks++;
                    trace("hit on X,Y");
                    trace("Block: " + totalBreaks + " / " +  totalBlocks);
                }

            }
        }

    }
4

1 回答 1

0

我不确定我是否正确，但我认为您的if else if陈述可能存在一个问题。

从您的示例中，调用 to可能会更改您和vars 的checkCollision()两倍，从而导致球在击中砖块时继续朝同一方向移动。dxdy

如果我是对的，那么您可以重构您的if陈述，如下所示：

if (level[ngrdy][ngrdx] > 0)
{
    [...]
}
else if (level[grdy][ngrdx] > 0)
{
    [...]
}
else if (level[ngrdy][grdx] > 0)
{
    [...]
}

此外，将简单的测试用括号括起来是一个好习惯。因此，不要这样写：

if (grdy <= level.length - 1 && ngrdy <= level.length - 1 && grdy >= 0 && ngrdy >= 0)

我会写这个：

if ((grdy <= level.length - 1) && (ngrdy <= level.length - 1) && (grdy >= 0) && (ngrdy >= 0))

从而使代码更具可读性。

干得好，继续加油！

编辑：正如您的评论表明这不是一个正确的答案，我再挖掘一点，现在我有另一个建议，使用一些布尔值来检查方向是否应该在两个轴上翻转。我还做了一些重构：

private function checkCollision():void
{
    grdx = Math.floor((ball.x) / 28);
    grdy = Math.floor((ball.y) / 14);
    ngrdx = Math.floor((ball.x + dx) / 28);
    ngrdy = Math.floor((ball.y + dy) / 14);

    var flipX:Boolean = false;
    var flipY:Boolean = false;


    if ((grdy <= level.length - 1) && (ngrdy <= level.length - 1) && (grdy >= 0 && ngrdy >= 0))
    {
        if (testBlock(grdx, ngrdy))
        {
            flipY = true;
        }
        if (testBlock(ngrdx, grdy))
        {
            flipX = true;
        }
        if (testBlock(ngrdx, ngrdy))
        {
            flipX = true;
            flipY = true;
        }

        dx *= flipX ? -1 : 1;
        dy *= flipY ? -1 : 1;
    }
}

private function testBlock(xPos:int, yPos:int):Boolean
{
    if (level[yPos][xPos] > 0)
    {
        trace("hit on X,Y");
        level[yPos][xPos] = 0;
        breakBlock("Block_" + yPos + "_" + xPos);
        trace("Block: " + totalBreaks + " / " + totalBlocks);
        return true;
    }
    return false;
}

private function breakBlock(blockName:String):void
{
    if (this.getChildByName(blockName))
    {
        this.removeChild(this.getChildByName(blockName));
        totalBreaks++;
    }
}

如果它碰巧是正确的解决方案，我会清理这个答案......

于 2013-03-19T01:53:50.193 回答