3

我正在尝试将图像（比如说黑白）转换为矩阵（其中 0 = 黑色，1 = 白色）

我试过这段代码：

procedure TForm1.Button1Click(Sender: TObject);
type
  tab = array[1..1000,1..1000] of byte;
var i,j: integer;
    s : string;
    image : TBitmap;
    t : tab;
begin
  image := TBitmap.Create;
  image.LoadFromFile('c:\image.bmp');

  s := '';
  for i := 0 to image.Height do
  begin
     for j := 0 to image.Width do
     begin
      if image.Canvas.Pixels[i,j] = clWhite then
        t[i,j] := 0
      else
        t[i,j] := 1;

     end;
  end;
  for i := 0 to image.Height do
  begin
    for j := 0 to image.Width do
     begin
      s:=s + IntToStr(t[i,j]);
     end;
     Memo1.Lines.Add(s);
     s:='';
  end;
end;

但它给了我错误的结果。

任何的想法？

4

3 回答 3

12

您的代码中有五个错误和另外两个问题！

首先，

for i := 0 to image.Height do

必须替换为

for i := 0 to image.Height - 1 do

（为什么？）同样，

for j := 0 to image.Width do

必须替换为

for j := 0 to image.Width - 1 do

其次，Pixels数组接受参数[x, y]，而不是[y, x]。因此，您需要更换

image.Canvas.Pixels[i,j]

经过

image.Canvas.Pixels[j,i]

第三，你写了“0 = black and 1 = white”，但显然你做了相反的事情！

第四，您尝试访问t[0, 0]，即使您的矩阵开始索引在1. 用来array[0..1000,0..1000] of byte;解决这个问题。

第五，您有内存泄漏（image未释放--使用try..finally）。

另外，最好使用动态数组：

type
  TByteMatrix = array of array of byte;

var
  mat: TByteMatrix;

你从

SetLength(mat, image.Height - 1, image.Width - 1);

如果你想让它索引[y, x]，否则相反。

最后，在这种情况下，您根本不应该使用该Pixels属性，因为它非常慢。相反，使用该Scanline属性。有关更多信息，请参阅此或那个或其他内容。

Memo1.Lines.BeginUpdate此外，只需在更新之前和Memo1.Lines.EndUpdate之后添加备忘录控件，您将获得很多速度。

于 2013-03-09T16:27:53.027 回答
5

以下过程将输入ABitmap位图转换为多维AMatrix字节数组，它表示像素，其中 0 值表示白色像素，1 表示任何其他颜色：

type
  TPixelMatrix = array of array of Byte;

procedure BitmapToMatrix(ABitmap: TBitmap; var AMatrix: TPixelMatrix);
type
  TRGBBytes = array[0..2] of Byte;
var
  I: Integer;
  X: Integer;
  Y: Integer;
  Size: Integer;
  Pixels: PByteArray;
  SourceColor: TRGBBytes;
const
  TripleSize = SizeOf(TRGBBytes);
begin
  case ABitmap.PixelFormat of
    pf24bit: Size := SizeOf(TRGBTriple);
    pf32bit: Size := SizeOf(TRGBQuad);
  else
    raise Exception.Create('ABitmap must be 24-bit or 32-bit format!');
  end;

  SetLength(AMatrix, ABitmap.Height, ABitmap.Width);
  for I := 0 to TripleSize - 1 do
    SourceColor[I] := Byte(clWhite shr (16 - (I * 8)));

  for Y := 0 to ABitmap.Height - 1 do
  begin
    Pixels := ABitmap.ScanLine[Y];
    for X := 0 to ABitmap.Width - 1 do
    begin
      if CompareMem(@Pixels[(X * Size)], @SourceColor, TripleSize) then
        AMatrix[Y, X] := 0
      else
        AMatrix[Y, X] := 1;
    end;
  end;
end;

AMatrix此过程将多维字节数组打印到AMemo备忘录框：

procedure ShowPixelMatrix(AMemo: TMemo; const AMatrix: TPixelMatrix);
var
  S: string;
  X: Integer;
  Y: Integer;
begin
  AMemo.Clear;
  AMemo.Lines.BeginUpdate;
  try
    AMemo.Lines.Add('Matrix size: ' + IntToStr(Length(AMatrix[0])) + 'x' +
      IntToStr(Length(AMatrix)));
    AMemo.Lines.Add('');

    for Y := 0 to High(AMatrix) do
    begin
      S := '';
      for X := 0 to High(AMatrix[Y]) - 1 do
      begin
        S := S + IntToStr(AMatrix[Y, X]);
      end;
      AMemo.Lines.Add(S);
    end;
  finally
    AMemo.Lines.EndUpdate;
  end;
end;

以及上述程序的用法：

procedure TForm1.Button1Click(Sender: TObject);
var
  Bitmap: TBitmap;
  PixelMatrix: TPixelMatrix;
begin
  Bitmap := TBitmap.Create;
  try
    Bitmap.LoadFromFile('d:\Image.bmp');
    BitmapToMatrix(Bitmap, PixelMatrix);
  finally
    Bitmap.Free;
  end;
  ShowPixelMatrix(Memo1, PixelMatrix);
end;

上述BitmapToMatrix过程的扩展允许您指定参数luminance给定的级别AMinIntensity将像素视为非白色。

该AMinIntensity值越接近 0，越亮的像素被视为非白色。这允许您使用颜色强度容差（例如，更好地识别抗锯齿文本）：

procedure BitmapToMatrixEx(ABitmap: TBitmap; var AMatrix: TPixelMatrix;
  AMinIntensity: Byte);
type
  TRGBBytes = array[0..2] of Byte;
var
  X: Integer;
  Y: Integer;
  Gray: Byte;
  Size: Integer;
  Pixels: PByteArray;
begin
  case ABitmap.PixelFormat of
    pf24bit: Size := SizeOf(TRGBTriple);
    pf32bit: Size := SizeOf(TRGBQuad);
  else
    raise Exception.Create('ABitmap must be 24-bit or 32-bit format!');
  end;

  SetLength(AMatrix, ABitmap.Height, ABitmap.Width);

  for Y := 0 to ABitmap.Height - 1 do
  begin
    Pixels := ABitmap.ScanLine[Y];
    for X := 0 to ABitmap.Width - 1 do
    begin
      Gray := 255 - Round((0.299 * Pixels[(X * Size) + 2]) +
        (0.587 * Pixels[(X * Size) + 1]) + (0.114 * Pixels[(X * Size)]));

      if Gray < AMinIntensity then
        AMatrix[Y, X] := 0
      else
        AMatrix[Y, X] := 1;
    end;
  end;
end;
于 2013-03-09T16:39:48.400 回答
-1

备忘录行位置下降，但您的循环 image.height 首先将在备忘录中反转结果，尝试此代码

procedure TForm1.Button1Click(Sender: TObject);
var i,j: integer;
    s : string;
    image : TBitmap;
begin
  image := TBitmap.Create;
  image.LoadFromFile('c:\image.bmp');

  s := '';
  for i := 0 to image.width-1 do
  begin
     for j := 0 to image.Height-1 do
     begin
      if image.Canvas.Pixels[i,j] = clWhite then
        s := s+'0'
      else
        s := s+'1';
     end;
     memo1.Lines.Add(s);
     s:='';
  end;
end;
于 2013-03-09T16:45:21.100 回答