3

我正在创建一个左修剪模板，我有以下模板：

<xsl:template name="str:left-trim">
    <xsl:param name="string" select="''"/>
    <xsl:variable name="tmp" select="substring($string, 1, 1)"/>

    <xsl:if test="$tmp = ' '">
        <xsl:variable name="tmp2" select="substring-after($string, $tmp)"/>
        <xsl:choose>
            <xsl:when test="$tmp2 != ''">
                <xsl:call-template name="str:left-trim">
                    <xsl:with-param name="string" select="$tmp2"/>        
                </xsl:call-template>
            </xsl:when>
            <xsl:otherwise>
                <xsl:value-of select="$tmp2"/>
            </xsl:otherwise>
        </xsl:choose>
    </xsl:if>
    <xsl:if test="$tmp != ' '">
        <xsl:value-of select="$string"/>
    </xsl:if>
</xsl:template>

如果我传递这样的论点：

<xsl:variable name="str-test2">this is a america</xsl:variable>

那么我的模板可以正常工作，但是如果我在下面传递这样的参数，我的模板将失败。我认为 break(newline) 有问题

    <xsl:variable name="str-test2">            
        this is a america
    </xsl:variable>

你有什么建议吗？

4

2 回答 2

4

这对我有用。注意我没有使用 str: 命名空间，而且我正在检查前导换行符。

<xsl:template name="left-trim">
  <xsl:param name="string" select="''"/>
  <xsl:variable name="tmp" select="substring($string, 1, 1)"/>

  <xsl:choose>
    <xsl:when test="$tmp = ' ' or $tmp = '&#xA;'">
      <xsl:call-template name="left-trim">
        <xsl:with-param name="string" select="substring-after($string, $tmp)"/>        
      </xsl:call-template>
    </xsl:when>
    <xsl:otherwise>
      <xsl:value-of select="$string"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:template>

HTH，阿克塞尔。

于 2009-12-07T13:23:19.960 回答
2

这是在 XSLT 1.0 中不使用递归模板左修剪字符串的解决方案：

<xsl:value-of select="substring($str-test2, string-length(substring-before($str-test2, substring(normalize-space($str-test2), 1, 1))) + 1)"/>
于 2013-02-28T00:15:35.150 回答