8

如何在批处理文件的环境变量中获取 Windows 控制台的当前宽度？

4

6 回答 6

12

mode我喜欢在 Windows中使用内置命令的方法。尝试以下批处理文件：

@echo off
for /F "usebackq tokens=2* delims=: " %%W in (`mode con ^| findstr Columns`) do set CONSOLE_WIDTH=%%W
echo Console is %CONSOLE_WIDTH% characters wide

请注意，这将返回控制台缓冲区的大小，而不是窗口的大小（可滚动）。

如果您想要 Windows 控制台的高度，可以Columns在findstr表达式中替换为Lines. 同样，它将返回缓冲区的高度，而不是窗口...我个人喜欢有一个大缓冲区来允许回滚历史，所以对我来说，Lines 通常报告大约 3000 :)

只是为了好玩，这是一个不findstr用于过滤输出的版本......以防万一（出于某种原因）您不喜欢findstr：

@echo off
for /F "usebackq tokens=1,2* delims=: " %%V in (`mode con`) do (
    if .%%V==.Columns (
        set CONSOLE_WIDTH=%%W
        goto done
    )
)
:done
echo Console is %CONSOLE_WIDTH% characters wide

请注意，这都是在 Windows XP SP3 中尝试过的，在许多不同的窗口中（包括一个正在执行的 FAR 管理器）。

于 2013-02-20T13:39:38.733 回答
5

试试这个（语言/区域设置/.net 独立）：

@ECHO OFF
SET "ConsoleWidth="
SET /A LINECOUNT=0
SETLOCAL ENABLEDELAYEDEXPANSION
FOR /F "tokens=1,2,*" %%A IN ('mode con') DO (SET /A LINECOUNT=!LINECOUNT!+1&IF !LINECOUNT! EQU 4 SET ConsoleWidth=%%B)
SETLOCAL DISABLEDELAYEDEXPANSION
SET "LINECOUNT="
ECHO ConsoleWidth: %ConsoleWidth% characters

在 Windows XP 和 Windows 7 上测试，均使用捷克语

于 2013-06-11T14:47:02.520 回答
2

Powershell 的(Get-Host).UI.RawUI.WindowSize属性设置或返回当前控制台窗口的尺寸。因此，您可以使用for循环捕获它：

for /f %%I in ('powershell ^(Get-Host^).UI.RawUI.WindowSize.width') do set width=%%I
于 2013-02-20T13:00:31.537 回答
1

好的，这是不需要安装powershell的。它编写、运行和删除 .Net 应用程序以设置批处理脚本变量。:)

@echo off
setlocal
pushd "%windir%\microsoft.net\"
for /f "delims=" %%I in ('dir /s /b csc.exe') do (
    set csc=%%I
    goto next
)
:next
popd
echo using System;>width.cs
echo class Width {>>width.cs
echo public static void Main() {>>width.cs
echo string m1 = "{0}";>>width.cs
echo Console.WriteLine^(m1, Console.WindowWidth^); } }>>width.cs
"%csc%" /out:width.exe width.cs >NUL 2>NUL
for /f %%I in ('width.exe') do set width=%%I
del width.exe width.cs
echo %width%
于 2013-02-20T13:35:04.850 回答
0

您无法在环境变量中获取它，但它存储在注册表中，因此您可以从批处理脚本中访问它。

这里有关于如何更改它的答案： How to change Screen buffer size in Windows Command Prompt from batch script

以类似的方式，您可以使用reg.exe QUERY [key details]而不是reg.exe ADD [details]. 有关详细信息，请参阅Technet 文档HKCU\Console。

于 2013-02-20T11:33:37.713 回答
0

对于一个简单的行：

for /f tokens^=2 %%w in ('mode con^|find "Col"')do set _width=%%~w"

于 2019-12-19T14:41:46.580 回答