7

我有Tiger's Pugmark（足迹印象）在泥土中的图像。我想检测 pugmark 的边界，但图像的强度是均匀的，即前景和背景无法根据强度变化来区分。我该怎么做才能区分 pugmark 和背景。！

老虎的pugmark

4

2 回答 2

9

在分段任务中，如果你有两者

  1. 良好的标记；和
  2. 感兴趣对象周围的强边缘

然后直接通过分水岭变换求解。当然，问题在于获得这些标记，以及根据需要增强相关边缘。获得这些可能涉及特定于问题的知识，我没有针对您的问题的知识。

不过，有一些通用方法可能有用。例如，数学形态学中的连接算子可用作合并和扩展平坦区域的一种方式。因此，也许它可以为我们提供相对较好的问题标记。在下图中，在原始图像（左图）的灰度版本中通过开运算（一种连接算子）进行了形态学重建，剩余的区域最大值显示在右侧。

在此处输入图像描述 在此处输入图像描述

现在，我们可以得到上图左图的形态梯度。我们还可以在上图中用一个小圆盘进行空洞填充和膨胀，以获得更平滑的轮廓——这定义了我们的标记图像。然后，使用我们的标记图像在渐变图像中应用分水岭变换，然后扩展（侵蚀或扩张，取决于你如何看待它）分水岭线，我们得到以下图像：

在此处输入图像描述

我怀疑您可以轻松丢弃太大和太小的区域。然后，如果您对爪子和手掌有一些粗略的预期尺寸，您可以丢弃不相关的区域。此时，只需将区域扩大以形成单个组件并在原始图像中显示生成的轮廓：

在此处输入图像描述

执行每个步骤的示例代码（相关步骤也显示在注释的 Matlab 代码中）：

f = Import["http://imageshack.us/a/img407/4636/p1060993g.jpg"]
g = ColorConvert[f, "Grayscale"]                           (* g = rgb2gray(f); *)
(* First image shown: *)
geo = GeodesicOpening[g, DiskMatrix[5]]  (* geo = imreconstruct(imerode(g, ... *)
                                         (*         strel('disk', 6)), g);     *)
(* Second image shown: *)
marker = MaxDetect[geo]                        (* marker = imregionalmax(geo); *)

(* Watershed on gradient with markers. *)
mgrad = ImageSubtract[Dilation[geo, 1], Erosion[geo, 1]]; (* mgrad = ...       *)
          (* imdilate(geo,strel('square',3)) - imerode(geo,strel('square',3)); *)
ws = Image[           (* ws = watershed(imimposemin(mgrad, bwmorph(imfill(...  *)
 WatershedComponents[mgrad,      (* imregionalmax(geo),'holes'),'dilate'))));  *)
  Dilation[FillingTransform[marker], DiskMatrix[1]]]]

(* Third image shown: *)
wsthick = Erosion[ws // ImageAdjust, DiskMatrix[5]]

(* Connected component selection based on some supposed sizes. *)
ccs = SelectComponents[wsthick, "Count", 1000 < # < 3000 || 6000 < # < 10000 &]

(* Final image (thick border on binarized filled dilated ccs) *)
res = ImageAdd[f, Dilation[MorphologicalPerimeter[FillingTransform[
     MorphologicalPerimeter[Dilation[ccs, DiskMatrix[9]]]]], 2]]
于 2013-02-18T14:42:25.420 回答
4

@mmpg 答案中的方法可能不稳定，因为使用的算法需要设置参数，这些参数可能特定于每个图像。使用对形状具有先验知识的参数模型似乎可以更好地解决这个问题。

主动形状模型框架迭代地逼近形状的边界。首先，你用一些平均形状初始化它（图像只是插图，不是算法的实际输出）：

形状的初始化

轮廓由锚点定义（由蓝色刻度显示，仅用于手掌以避免混乱）。在每次迭代中，算法考虑每个锚点的正交方向并估计每个距离处边界的概率（通常使用图像梯度，但在您的情况下它应该更复杂 - 可能是纹理的差异，例如直方图之间的距离的文本）。此处红点突出显示该分布的 arg 最大值：

边缘分布的模式

然后将新轮廓拟合到数据以最大化这些分布乘以形状的先验分布。假设先验均匀，新轮廓将如下所示：

新的轮廓

在实践中，您希望有一个非平凡的形状分布。要估计这一点，您将需要一组训练图像，其中 pugmark 掩码是手动标记的。

您可能想尝试这个 MATLAB 实现。

于 2013-02-19T18:15:00.760 回答