0

我是 Perl 的新手，必须编写一个代码，将文件的内容放入数组并打印看起来像哈希的输出。 这是一个示例条目：

my %amino_acids = (F => ["Phenylalanine", "Phe", ["TTT", "TTC"]])

输出应完全采用上述格式。

文件行是这样的......

"Methionine":"Met":"M":"AUG":"ATG"
"Phenylalanine":"Phe":"F":"UUU, UUC":"TTT, TTC"
"Proline":"Pro":"P":"CCU, CCC, CCA, CCG":"CCT, CCC, CCA, CCG"

我必须在分号后取最后一个密码子并忽略第一组。

4

4 回答 4

3

您是否打算构建等效哈希？还是您真的想要字符串格式？该程序用于Text::CSV从文件构建散列，然后使用转储它，Data::Dump以便您也拥有字符串格式。

use strict;
use warnings;

use Text::CSV;
use Data::Dump 'dump';

my $csv = Text::CSV->new({ sep_char => ':' });
open my $fh, '<', 'amino.txt' or die $!;

my %amino_acids;
while (my $data= $csv->getline($fh)) {
  $amino_acids{$data->[2]} = [
    $data->[0],
    $data->[1],
    [ $data->[4] =~ /[A-Z]+/g ]
  ];
}

print '$amino_acids = ', dump \%amino_acids;

输出

$amino_acids = {
  F => ["Phenylalanine", "Phe", ["TTT", "TTC"]],
  M => ["Methionine", "Met", ["ATG"]],
  P => ["Proline", "Pro", ["CCT", "CCC", "CCA", "CCG"]],
}

更新

如果您真的不想安装模块（这是一个非常简单的过程，并且使代码更加简洁和可靠），那么这就是您所需要的。

use strict;
use warnings;

open my $fh, '<', 'amino.txt' or die $!;

print "my %amino_acids = (\n";

while (<$fh>) {
  chomp;
  my @data = /[^:"]+/g;
  my @codons = $data[4] =~ /[A-Z]+/g;
  printf qq{  %s => ["%s", "%s", [%s]],\n},
      @data[2,0,1],
      join ', ', map qq{"$_"}, @codons;
}

print ")\n";

输出

my %amino_acids = (
  M => ["Methionine", "Met", ["ATG"]],
  F => ["Phenylalanine", "Phe", ["TTT", "TTC"]],
  P => ["Proline", "Pro", ["CCT", "CCC", "CCA", "CCG"]],
)
于 2013-02-17T12:35:26.997 回答
0

假设您实际上想要有效的 perl 作为输出，这将做到：

open(my $IN, "<input.txt") or die $!;

while(<$IN>){
    chomp;
    my @tmp = split(':',$_);
    if(@tmp != 5){
        # error on this line
        next;
    }
    my $group = join('","',split(/,\s*/,$tmp[4]));
    print "\$amino_acids{$tmp[2]} = [$tmp[0],$tmp[1],[$group]];\n";
}
close $IN;

使用您的示例行，输出为：

$amino_acids{"M"} = ["Methionine","Met",["ATG"]];
$amino_acids{"F"} = ["Phenylalanine","Phe",["TTT","TTC"]];
$amino_acids{"P"} = ["Proline","Pro",["CCT","CCC","CCA","CCG"]];
于 2013-02-17T07:59:12.050 回答
0

@Borodin 非常感谢您的回答，实际上我不必使用 Text::csv 或 Data::dump。我必须打开一个文件并从文件中构建等效的哈希值。我试图不使用两者，希望它会有所帮助。再次感谢！

于 2013-02-17T14:31:43.933 回答
-1

Perl 没有打印散列的特殊方法。您可能应该做的是在读取文件时创建一个哈希：

while (<FILE>) {
    my @line = split ':'; # split the line into an array
    $amino_acids{$line[0]} = \@line[1..-1]; # take elements 1..end 
}

然后一次打印出一个条目的哈希值：

foreach (keys %amino_acids) {
    print "$_ => [", (join ",", @$amino_acids{$_}), "]\n";
}

请注意，我没有编译这个，所以它可能需要少量的工作来完成它。

于 2013-02-17T07:42:20.297 回答