2

我有一个 TidTCPServer，它在 onExcecute 事件中使用数据库操作（通过使用 TidNotify）。一切都很好，而不是可能关闭应用程序。在关闭应用程序期间，我不知道所有通知实例是否都完成了工作，通常我得到运行时错误 216（我想我在“通知”工作结束之前关闭了数据库）。有什么方法可以检查 - 是否有等待旧的通知帖子或不确定我可以关闭应用程序。另一个问题是如何保护 TidTCPServer 在关闭服务器过程中不接受新连接。我使用下面的代码，但我仍然得到错误。

type
  TShutdownThread = class(TThread)
  protected
    procedure Execute; override;
  end;


procedure TShutdownThread.Execute;
begin
  IdTCPServer.Active := false;
end;


//closing...
  if IdTCPServer.Active then
  begin
    with TShutdownThread.Create(false) do
      try
        WaitFor; // internally processes sync requests...
      finally
        Free;
      end;
  end;
4

1 回答 1

3

有什么方法可以检查 - 是否有等待旧的通知帖子或不确定我可以关闭应用程序。

TIdNotify是异步的，它将请求发布到主线程消息队列以供稍后执行。TShutdownThread.WaitFor()退出后，待处理的请求可能仍在队列中。您可以调用 RTL 的CheckSynchronize()函数来处理任何剩余的请求，例如：

if IdTCPServer.Active then
begin
  with TShutdownThread.Create(false) do
  try
    WaitFor;
  finally
    Free;
  end;
  CheckSynchronize;
end;

如何保护 TidTCPServer 在关闭服务器过程中不接受新连接。

在TIdTCPServer停用期间，它会为您关闭其侦听端口。但是，在服务器关闭端口之前可以接受新客户端的机会窗口非常小。服务器将关闭这些连接作为其关闭的一部分，但如果您不希望OnExecute为这些连接调用事件，那么您可以在停用服务器之前在代码中的某处设置一个标志，然后在OnConnect事件中检查该标志，如果已设置，则立即断开客户端连接，例如：

var
  ShuttingDown: boolean = False;

procedure TForm1.IdTCPServer1Connect(AContext: TIdContext);
begin
  if ShuttingDown then
  begin
    AContext.Connection.Disconnect;
    Exit;
  end;
  ...
end;

...

if IdTCPServer.Active then
begin
  ShuttingDown := True;
  try
    with TShutdownThread.Create(false) do
    try
      WaitFor;
    finally
      Free;
    end;
    CheckSynchronize;
  finally
    ShuttingDown := False;
  end;
end;
于 2013-02-17T22:16:40.417 回答