3

我有一个语法，在这部分之前一切正常：

lexp
: factor ( ('+' | '-') factor)* 
;

factor :('-')? IDENT;

这当然引入了歧义。例如a-a，可以通过或者Factor - Factor匹配Factor -> - IDENT

我收到以下警告说明：

[18:49:39] warning(200): withoutWarningButIncomplete.g:57:31: 
Decision can match input such as "'-' {IDENT, '-'}" using multiple alternatives: 1, 2

我该如何解决这种歧义？我只是没有办法解决它。我可以使用某种选项吗？

这是完整的语法：

program 
    : includes decls (procedure)*
    ;

/* Check if correct! */
includes
    :  ('#include' STRING)* 
    ;

decls
    : (typedident ';')*
    ;

typedident
: ('int' | 'char') IDENT    
;

procedure
    : ('int' | 'char') IDENT '(' args ')' body
    ;

args
: typedident (',' typedident )*  /* Check if correct! */
|   /* epsilon */ 
;

body
: '{' decls stmtlist '}'
;   

stmtlist
: (stmt)*;

stmt  

:  '{' stmtlist '}'
| 'read' '(' IDENT ')' ';'
| 'output' '(' IDENT ')' ';'
| 'print' '(' STRING ')' ';'
| 'return' (lexp)* ';'
| 'readc' '(' IDENT ')' ';'
| 'outputc' '(' IDENT ')' ';'
|  IDENT '(' (IDENT ( ',' IDENT )*)? ')' ';'
| IDENT '=' lexp ';';



lexp
: term (( '+' | '-' ) term) * /*Add in | '-'  to reveal the warning! !*/
;

term 
    : factor (('*' | '/' | '%') factor )*
;  


factor : '(' lexp ')' 
 | ('-')? IDENT
 | NUMBER;




fragment DIGIT
: ('0' .. '9')
;

IDENT : ('A' .. 'Z' | 'a' .. 'z') (( 'A' .. 'Z' | 'a' .. 'z' | '0' .. '9' | '_'))* ;


NUMBER
: ( ('-')? DIGIT+)
;

CHARACTER
: '\'' ('a' .. 'z' | 'A' .. 'Z'  | '0' .. '9' | '\\n' |  '\\t'  | '\\\\'  | '\\'  | 'EOF'  |'.' | ',' |':'  )  '\'' /* IS THIS COMPLETE? */
;
4

1 回答 1

2

正如评论中提到的：这些规则并不模棱两可：

lexp
 : factor (('+' | '-') factor)* 
 ;

factor : ('-')? IDENT;

这是模棱两可的原因：

'return' (lexp)* ';'

a-b它可以以两种不同的方式解析输入：

  1. a-b作为单个二进制表达式
  2. a作为单个表达式和-b一元表达式

你需要改变你的语法。也许在多个返回值中添加逗号？像这样的东西：

'return' (lexp (',' lexp)*)? ';'

这将匹配：

return;
return a;
return a, -b;
return a-b, c+d+e, f;
...
于 2013-02-12T22:16:40.390 回答