delphi - 如何在 TListView 列上显示排序箭头？

Question

Windows 资源管理器有一个箭头，指示列表视图（报表视图样式）的排序依据和方向（ASC 与 DESC）。

TListView是否可以在 Delphi中显示这样的排序指示箭头？

Answer 1

这是一些将标题列标记为升序排序的简单代码：

uses
  Winapi.CommCtrl;

var
  Header: HWND;
  Item: THDItem;
begin
  Header := ListView_GetHeader(ListView1.Handle);
  ZeroMemory(@Item, SizeOf(Item));
  Item.Mask := HDI_FORMAT;
  Header_GetItem(Header, 0, Item);
  Item.fmt := Item.fmt and not (HDF_SORTUP or HDF_SORTDOWN);//remove both flags
  Item.fmt := Item.fmt or HDF_SORTUP;//include the sort ascending flag
  Header_SetItem(Header, 0, Item);
end;

为了简单起见，我省略了错误检查。如果你想要相反方向的箭头，我相信你可以弄清楚如何交换逻辑。

MSDN 的关键主题是HDITEM结构。

Answer 2

您可以轻松地扩展此代码，使其适用于 ListView 中的所有列；声明两个变量（在表单的私有部分）：

ColumnToSort：整数；升序：布尔值；

在 FormCreate 过程中用 0 和 True 初始化它们。

procedure TForm1.ListView1ColumnClick(Sender: TObject; Column: ListColumn);
var
  Header: HWND;
  Item: THDItem;
begin
  Header := ListView_GetHeader(ListView1.Handle);
  ZeroMemory(@Item, SizeOf(Item));
  Item.Mask := HDI_FORMAT;

  // Clear the previous arrow
  Header_GetItem(Header, ColumnToSort, Item);
  Item.fmt := Item.fmt and not (HDF_SORTUP or HDF_SORTDOWN);//remove both flags
  Header_SetItem(Header, ColumnToSort, Item);

  if Column.Index = ColumnToSort then
    Ascending := not Ascending
  else
    ColumnToSort := Column.Index;

  // Get the new column
  Header_GetItem(Header, ColumnToSort, Item);
  Item.fmt := Item.fmt and not (HDF_SORTUP or HDF_SORTDOWN);//remove both flags

  if Ascending then
    Item.fmt := Item.fmt or HDF_SORTUP//include the sort ascending flag
  else
    Item.fmt := Item.fmt or HDF_SORTDOWN;//include the sort descending flag
  Header_SetItem(Header, ColumnToSort, Item);

  with ListView1 do
    begin
      Items.BeginUpdate;
      AlphaSort;
      Items.EndUpdate;
    end;
end;

当然，您必须为列的实际排序提供自己的 OnCompare 函数。此代码仅在单击的列标题中显示排序箭头。