sql - 解析数学函数 PL/SQL

Question

我需要解决 pl/sql 中的数学方程/函数。
oracle pl/sql 中有哪些数学运算/函数可以帮助我解决这样的数学函数：

(3.5/(1+x))+(3.5/(1+x)^2)+(3.5/(1+x)^3)+(3.5/(1+x)^4)+(100/(1+x)^4)=101.55

我想要一个函数来解析这个语句并找出x.

像这样的东西是我正在寻找的

有什么帮助吗？谢谢。

Answer 1

唉，Oracle 数据库不是数学工具。它有很多算术和统计函数，但它没有能够解释方程的内置功能。对不起。

---

纯属巧合，Marc (AKA Odie_63 ) 最近发布了一个他用 PL/SQL 编写的逆波兰表示法计算器。它并不完全符合您的要求，但我提供了一个链接，以供将来可能偶然发现此线程的任何寻求者的利益。 找到更多。

Answer 2

正如 APC 所说，没有内置功能可以做到这一点。但是您可以使用 PL/SQL 中的WolframAlpha API：

declare
    v_equation varchar2(32767) := 
        '(3.5/(1+x))+(3.5/(1+x)^2)+(3.5/(1+x)^3)+(3.5/(1+x)^4)+(100/(1+x)^4)=101.55';
    v_escaped_url varchar2(32767);
    v_uri httpuritype;
    v_xml xmltype;
    v_count number := 1;
begin
    --Escape the URL.
    --I used chr(38) for ampersand, in case your IDE think it's a substitution variable
    v_escaped_url :=
        'http://api.wolframalpha.com/v2/query?appid=EQGHLV-UYUEYY9ARU'||chr(38)||'input='
        ||utl_url.escape(v_equation, escape_reserved_chars => true)
        ||chr(38)||'format=plaintext';

    --Create an HTTPURIType, and get the XML
    v_uri := httpuritype.createUri(v_escaped_url);
    v_xml := v_uri.getXML;

    --Complex solutions
    while v_xml.existsNode('/queryresult/pod[@title="Complex solutions"]/subpod['||v_count||']') = 1 loop
        dbms_output.put_line(v_xml.extract('/queryresult/pod[@title="Complex solutions"]/subpod['||v_count||']/plaintext/text()').getStringVal());
        v_count := v_count + 1;
    end loop;

    --Real solutions
    v_count := 1;
    while v_xml.existsNode('/queryresult/pod[@title="Real solutions"]/subpod['||v_count||']') = 1 loop
        dbms_output.put_line(v_xml.extract('/queryresult/pod[@title="Real solutions"]/subpod['||v_count||']/plaintext/text()').getStringVal());
        v_count := v_count + 1;
    end loop;
end;
/

结果：

x = -1.00006-0.996229 i
x = -1.00006+0.996229 i
x = -1.99623
x = 0.0308219

这种方法有很多潜在的缺点。它会很慢，而且 API 不是免费的。我的示例有效，因为我使用了免费的开发者 appid，但它只适用于少量调用。