3

正如标题所示，我想将图例放置在多图图下方。我只为其中一个图添加了图例，因为所有的线型都相同。我遇到的问题是，如果我通过添加键set key below，绘图本身会被调整大小以适合画布内的（大）键。我宁愿保持地块的大小。我尝试使用 将密钥添加为多图中的附加图set key inside，但如果它太大，则密钥可能会与图重叠。我正在使用 epslatex 终端。

4

2 回答 2

8

这是一种使用一些函数来帮助调整绘图中边距位置的方法：

#!/usr/bin/env gnuplot

### n: change this parameter to equal the number of data sets to be plotted
n = 3
# t: top margin in pixels
t = 75.0
# b: key height in pixels (bottom margin)
b = 300.0
# h: height of output in pixels
h = 150.0*n + t + b

### define functions to help set top/bottom margins
top(i,n,h,t,b) = 1.0 - (t+(h-t-b)*(i-1)/n)/h
bot(i,n,h,t,b) = 1.0 - (t+(h-t-b)*i/n)/h

### first set up some basic plot parameters
set term pngcairo enhanced size 800,h font 'FreeMono-Bold,14'
set output 'bigkey.png'

set title 'Big Key Plot'
set ylabel 'Y Axis'

set multiplot layout (n+1),1
### First plot
# change only plot command here
currentplot = 1
set tmargin at screen top(currentplot,n,h,t,b)
set bmargin at screen bot(currentplot,n,h,t,b)
unset key
unset xtics
plot sin(1*x) title 'Line 1', \
     sin(2*x) title 'Line 2', \
     sin(3*x) title 'Line 3', \
     sin(4*x) title 'Line 4', \
     sin(5*x) title 'Line 5', \
     sin(6*x) title 'Line 6', \
     sin(7*x) title 'Line 7'
### Middle plot
# copy and paste this code to make more middle plots
currentplot = currentplot + 1
set tmargin at screen top(currentplot,n,h,t,b)
set bmargin at screen bot(currentplot,n,h,t,b)
unset title
replot
### Last plot
# change only plot command here
currentplot = currentplot + 1
set tmargin at screen top(currentplot,n,h,t,b)
set bmargin at screen bot(currentplot,n,h,t,b)
set xlabel 'X Axis'
set xtics
replot
### Last (key) plot
set tmargin at screen bot(n,n,h,t,b)
set bmargin at screen 0
set key center center
set border 0
unset tics
unset xlabel
unset ylabel
set yrange [0:1]
plot 2 t 'Line 1', \
     2 t 'Line 2', \
     2 t 'Line 3', \
     2 t 'Line 4', \
     2 t 'Line 5', \
     2 t 'Line 6', \
     2 t 'Line 7'

unset multiplot

结果如下： 在此处输入图像描述

您必须手动调整的内容是绘图的数量和底部边距的大小，这是绘制关键点的位置。评论通常会说明您必须在哪里进行更改。

我将密钥单独放在一个情节中，以便很容易保持其他情节的大小完全相同。当 y 范围为 0 到 1 时绘制数字 2 可防止线条显示在关键图中。

这主要基于我在这里的回答，这就是为什么我的情节都很感人。如果您想要图之间的间隙，您可以使用附加边距参数调整 top() 和 bot() 函数。

于 2013-02-06T17:40:54.107 回答
7

如果没有更多细节，很难知道这是否有用，但 gnuplot 允许您以绝对值指定键的位置：

set key at screen 0.5,screen 0.1 #for example

这可能使您可以将其移动到您想要的任何位置...

于 2013-02-05T18:10:49.480 回答