5

我正在编写的 Windows 批处理文件有点麻烦。

我需要批处理文件将一些特定的行写入另一个批处理文件，我一直使用的方法是：

type NUL > batchfile.bat
ECHO texttobewrittentofile >> batchfile.bat
ECHO texttobewrittentofile >> batchfile.bat
ECHO texttobewrittentofile >> batchfile.bat
...
etc

大多数行都写得很好，但是我的批处理文件写入另一个批处理文件时遇到了一些不同的问题。

我的批处理文件写入另一个批处理文件的代码是：

ECHO @echo off >> GenerateEmail.bat
ECHO ECHO Opening Stunnel >> GenerateEmail.bat
ECHO pushd .\stunnel\ >> GenerateEmail.bat
ECHO start "" stunnel.exe stunnel.conf >> GenerateEmail.bat
ECHO popd >> GenerateEmail.bat
ECHO ECHO Determining latest log for use with blat >> GenerateEmail.bat
ECHO pushd O:\Logs\%clientname%\ >> GenerateEmail.bat
ECHO for /f "tokens=*" %%a in ('dir /b /od') do set newest=%%a >> GenerateEmail.bat
ECHO popd >> GenerateEmail.bat
ECHO ECHO Generating email containing contents of latest log >> GenerateEmail.bat
ECHO pushd .\blat307\full\ >> GenerateEmail.bat
ECHO ECHO Y | xcopy "O:\Logs\%clientname%\%newest%" ".\" >> GenerateEmail.bat
ECHO blat.exe "%newest%" -to %clientemail% -cc %gmailemail% -server 127.0.0.1:1099 -subject "Offsite Backup for "%1" "%2" - %clientname%" -sig sig.txt >> GenerateEmail.bat
ECHO DEL .\*.log >> GenerateEmail.bat
ECHO popd >> GenerateEmail.bat
ECHO ECHO Closing Stunnel >> GenerateEmail.bat
ECHO pushd .\stunnel\ >> GenerateEmail.bat
ECHO stunnel.exe -exit >> GenerateEmail.bat
ECHO popd >> GenerateEmail.bat

我没有得到我想要的输出，我遇到了以下问题：

ECHO Y | xcopy "O:\Logs\%clientname%\%newest%" ".\" >> GenerateEmail.bat

出来作为

0 File(s) copied

在我需要 %% 的任何地方，它都以 % 的形式出现，并且以“blat.exe”开头的行在其他问题中根本没有写入。有没有办法让批处理文件写入文本行而不确认这些行中包含的任何命令或符号？

凯恩。

4

1 回答 1

10

所有像这样的特殊字符都^ & | < >必须转义为^^ ^& ^| ^< ^>或用引号括起来。

每个百分比都必须始终翻倍。例如：

  • "%1"变成"%%1"
  • %newest%变成%%newest%%
  • %%a变成%%%%a

如果在所有 ECHO 语句周围加上括号，则无需清除输出文件并重定向每一行。如果这样做，右括号也必须转义。

>GenerateEmail.bat (
  echo Line 1
  echo Line 2
  echo these must be escaped ^^ ^& ^| ^> ^< ^), these not "^ & | > < )"
)

如果您启用了延迟扩展并且您的输出包含!或!with ，则规则会变得更加复杂^。

还有其他方法可以避免必须弄清楚如何转义特殊字符和加倍百分比。

您可以为每行添加前缀:::并将 FOR /F 与 FINDSTR 一起使用以获得所需的输出。如果您的输出包含!. 下面代码的唯一限制是您的输出行不能以:（它可以以空格开头，后跟:）开头。

(for /f "tokens=* delims=:" %%L in ('findstr /b ::: "%~f0"') do echo %%L) >GenerateEmail.bat
:::echo special chars & | < > don't need to be escaped
:::echo % does not need to be doubled
::: :Label
::: :: Comment and label must be indented with at least one space
:::etc

另一种选择是使用以下技术之一：

于 2013-01-30T12:48:26.597 回答