8

我是 vim 用户，最近才开始使用 zsh 以便能够在 shell 中使用 vi 模式（由于缺少插入/命令模式指示器，这在 bash 中不实用）。在阅读了一些示例之后，我设置了以下函数来相应地更新行（我选择了与 vim-powerline 匹配的颜色方案，我也使用了）：

vim_ins_mode="%{$fg[white]%}%{$fg_bold[blue]$bg[white]%} INSERT %{$reset_color%}"
vim_cmd_mode="%{$fg[green]%}%{$fg_bold[black]$bg[green]%} COMMAND %{$reset_color%}"
vim_mode=$vim_ins_mode
function zle-line-init zle-keymap-select {
    RPS1="${${KEYMAP/vicmd/${vim_cmd_mode}}/(main|viins)/${vim_ins_mode}}"
    RPS2=$RPS1
    zle reset-prompt
}
zle -N zle-line-init
zle -N zle-keymap-select

它工作得很好，除了当我运行更多命令时，以前命令的 RPS1 会输出到屏幕上。你可以想象，在我的终端上放多个明亮的盒子会让人分心： 这是一个例子

我希望以某种方式清除该字段，然后将其作为先前的命令转储到行缓冲区中，但到目前为止，我查看的示例和 zsh 主题都没有打扰这样做。在我的旧 .bashrc 文件中，我有一个陷阱设置来重置我的命令的颜色，这样输出颜色就不会受到影响，我想知道这里是否有类似的可能？或者也许 zsh 有更清洁的方法？

4

1 回答 1

11

试试下面的代码：

function _-accept-line()
{
    emulate -L zsh
    local SAVEDRPS1="$RPS1"
    RPS1=""
    zle reset-prompt
    RPS1="$SAVEDRPS1"
    zle .accept-line
}
zle -N accept-line _-accept-line

忘记这段代码。Zsh 可以选择您想要的行为：

setopt transientrprompt

接受命令行时从显示中删除任何正确提示。这对于使用其他剪切/粘贴方法的终端可能很有用。

于 2013-01-15T14:39:07.190 回答