7

我遇到了一个小问题。

XSL 文件：

<?xml version="1.0" encoding="UTF-8"?> 
<xsl:stylesheet version="1.0"  
xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
xmlns:fn="http://www.w3.org/2005/xpath-functions"> 
<xsl:template match="/"> 


<xsl:variable name="unumericValue" select="10" />
<xsl:variable name="uanotherValue" select="8" />



<xsl:for-each select="/root/try">
<xsl:value-of select="var" />
<xsl:variable name="min"><xsl:value-of select="@minimum" /></xsl:variable>
<xsl:value-of select="@type" />
<xsl:variable name="referenceName"><xsl:value-of select='concat("u",var)' /></xsl:variable>
<xsl:value-of select="$referenceName" />
<xsl:if test='$referenceName > $min'>
<p>Do something.</p>
</xsl:if>
</xsl:for-each>

</xsl:template>
</xsl:stylesheet>

XML 文件：

<?xml version="1.0" encoding="UTF-8"?>
<?xml-stylesheet type="text/xsl" href="q1.xsl"?>
<root>
<try type="compare" minimum="9">
<var>numericValue</var>
<something>...</something>
</try>

<try type="compare" minimum="10">
<var>anotherValue</var>
<something>...</something>
</try>
</root>

如您所见，XML 文件有两个 var-Element，它们应该与 XSLT 文件中的变量匹配。但是我不知道哪种语法是正确的。$referenceName 只是我要使用的变量的名称。但我不知道如何将名称引用到现有变量。

4

3 回答 3

11

$referenceName不是对名为“unumericValue”或其他名称的变量的引用。它只是字符串值“unumericValue”等。所以它永远不会大于$min. 然而，通过一些额外的工作，有一个技巧可以通过它的名字找到一个变量：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:variable name="numericValue" select="10" />
  <xsl:variable name="anotherValue" select="8" />
  <xsl:variable name="vars" select="document('')/*/xsl:variable" />

  <xsl:template match="/">
    <xsl:variable name="referenceName" select="'numericValue'" />
    <xsl:variable name="referenceValue" select="$vars[@name = $referenceName]/@select" />
    Reference value: <xsl:value-of select="$referenceValue" />
  </xsl:template>
</xsl:stylesheet>

这里要注意的一大限制是，这仅适用于常量数值的变量。

这是一种使用常量字符串值模拟变量的方法：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                 xmlns:v="variables-node"
>
  <v:variables>
    <v:variable n="numericValue" value="10" />
    <v:variable n="nonNumericValue" value="Hello World" />
  </v:variables>
  <xsl:variable name="vars" select="document('')//v:variables/v:variable" />

    <xsl:template match="/">
      <xsl:variable name="referenceName" select="'nonNumericValue'" />
      <xsl:variable name="referenceValue" select="$vars[@n = $referenceName]/@value" />
      <xsl:value-of select="concat('The variable with the name ', $referenceName, ' has the value ', $referenceValue)"/>
    </xsl:template>
</xsl:stylesheet>

最后，一种用计算值模拟变量的方法：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" 
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
                xmlns:exslt="http://exslt.org/common"
>

  <xsl:variable name="varsRaw">
    <var n="computedValue" value="{concat('2 + 4 is ', 2 + 4)}" />
    <var n="computedNumber" value="{22 div 7}" />
  </xsl:variable>
  <xsl:variable name="vars" select="exslt:node-set($varsRaw)/var" />

    <xsl:template match="/">
      <xsl:variable name="referenceName" select="'computedValue'" />
      <xsl:variable name="referenceValue" select="$vars[@n = $referenceName]/@value" />
      <xsl:value-of select="concat('The variable with the name ', $referenceName, ' has the value ', $referenceValue)"/>

      <xsl:value-of select="'     '"/>

      <xsl:variable name="referenceName2" select="'computedNumber'" />
      <xsl:variable name="referenceValue2" select="$vars[@n = $referenceName2]/@value" />
      <xsl:value-of select="concat('The variable with the name ', $referenceName2, ' has the value ', $referenceValue2)"/>
    </xsl:template>
</xsl:stylesheet>

最后一种方法实际上可能是最正统的，但需要依赖于 XSLT 处理器（至少在 XSLT 1.0 中）的node-set()功能。

于 2013-01-10T17:37:05.363 回答
6

顺便说一句，不要这样做：

<xsl:variable name="min"><xsl:value-of select="@minimum" /></xsl:variable>

你什么时候可以这样做：

<xsl:variable name="min" select="@minimum" />

它不仅冗长，而且效率低下 - 无需复制数据并构建新树，这是一项非常昂贵的操作，而您只需要对现有节点的引用。

于 2013-01-10T22:11:58.313 回答
1

与大多数编程语言一样，XSLT 变量名在运行时不可访问。该变量甚至可能在运行时不存在 - 优化器可以发挥各种技巧，例如在使用变量时内联对变量的所有引用。

最好的方法是使用标准名称的变量，并为其提供 XML 内容。XML 中的元素和属性名称可在运行时访问，这与变量名称不同。

于 2013-01-10T21:46:31.870 回答