3

问题

我正在尝试构建一个最小的示例，在其中创建多对多关系DBIx::Class并将一些行插入数据库。

在我的数据库中，我有两个表A和C，它们由表AC链接。我尝试使用以下脚本插入值：

#! /usr/bin/perl
use strict;
use warnings;
use DB::Main;

my $s = DB::Main->connect("dbi:SQLite:example.db");
my $a1 = $s->resultset('A')->create({a_value => 'a1'});
my $a2 = $s->resultset('A')->create({a_value => 'a2'});
my $a3 = $s->resultset('A')->create({a_value => 'a3'});

$s->resultset('C')->create({c_value => 'c1'});
$s->resultset('C')->create({c_value => 'c2'});

my $c1 = $s->resultset('C')->find(1);
$c1->add_to_as($a1);

a1 到 a3 和 c1,c2 的值创建得很好。当我尝试将 a1 和 c1 之间的关系添加到表AC中时。我收到以下错误消息：

Can't use an undefined value as a HASH reference at /Library/Perl/5.12/DBIx/Class/Relationship/ManyToMany.pm line 88.

我想我正在关注add_to_$rel的文档。我在这里做错了什么？

模式定义

我正在使用以下数据库架构，将其部署DBIx::Class::DeploymentHandler到 SQLite 数据库中。

文件db/Main.pm

package DB::Main;
use base qw/DBIx::Class::Schema/;

our $VERSION = 1;
__PACKAGE__->load_namespaces;
1;

文件db/Main/Result/A.pm

package DB::Main::Result::A;
use base qw/DBIx::Class::Core/;
__PACKAGE__->table('a');
__PACKAGE__->add_columns(
  a_id => {
    data_type => 'Integer',
    size      => 8
  },
  a_value => {
    data_type => 'Varchar',
    size      => 50
  },
);
__PACKAGE__->set_primary_key('a_id');
__PACKAGE__->has_many('acs' => 'DB::Main::Result::AC', 'f_a_id');
__PACKAGE__->many_to_many('cs' => 'DB::Main::Result::C', 'acs');
1;

文件db/Main/Result/C.pm

package DB::Main::Result::C;
use base qw/DBIx::Class::Core/;
__PACKAGE__->table('c');
__PACKAGE__->add_columns(
  c_id => {
    data_type => 'Integer',
    size      => 8
  },
  c_value => {
    data_type => 'Varchar',
    size      => 50
  },
);
__PACKAGE__->set_primary_key('c_id');
__PACKAGE__->has_many('acs' => 'DB::Main::Result::AC', 'f_c_id');
__PACKAGE__->many_to_many('as' => 'DB::Main::Result::A', 'acs');
1;

文件db/Main/Result/AC.pm

package DB::Main::Result::AC;
use base qw/DBIx::Class::Core/;
__PACKAGE__->table('ac');
__PACKAGE__->add_columns(
  f_a_id => {
    data_type => 'Integer',
    size      => 8
  },
  f_c_id => {
    data_type => 'Integer',
    size      => 8
  },
);
__PACKAGE__->set_primary_key('f_a_id', 'f_c_id');
__PACKAGE__->belongs_to('a' => 'DB::Main::Result::A', 'f_a_id');
__PACKAGE__->belongs_to('c' => 'DB::Main::Result::C', 'f_c_id');
1;
4

1 回答 1

3

您对 many_to_many 的调用中的参数是错误的。请查阅 many_to_many 的文档并尝试以下操作：

__PACKAGE__->many_to_many('cs' => 'acs', 'c');
__PACKAGE__->many_to_many('as' => 'acs', 'a');
于 2013-01-09T20:03:13.173 回答