4

最近我一直在 Prolog 中使用 DCG，但我一直面临一些关于它如何工作的问题。例如，我有这个小语法：

<atom> :: <letter> <atom_part> | <letter>
<atom_part> :: <letter> | <digit> | <letter> <atom_part> | <digit> <atom_part>
<letter>:: 'a' | 'b' ... |'Z'
<digit> :: '0' |...|'9'

如果我没记错的话，它是任何必须以字母开头的字母或数字字符串。无论如何，我解析它的尝试如下：

letter("a") --> "a".
number(X) --> number(X).
...
%etc
programme(I) --> atomm(I).
atomm(C) --> letter(Ch).
atomm(C) --> numb(Ch).
atomm((E)) --> atomm_part(E).
atomm_part(E1,E2) --> atomm(E1),!,atomm(E2).

在这里，我认为很明显最后两行是错误的。这真的是因为我不确定如何进行“递归调用”，所以解析器再次检查字符串中的下一个字符是数字还是字符串。我该如何纠正？提前致谢！

顺便说一句，我正在使用 swi-prolog

4

1 回答 1

3

您的语法似乎比需要的复杂，您可以使用 'epsilon' （空产生式，在 DCG 中是[]）来简化它。除此之外，您应该使“程序”更加符合规范。

atom --> letter, atom_part | letter.
atom_part --> letter | digit | letter, atom_part | digit, atom_part.
letter --> "a" | "b" | /* omissis... */ "Z".
digit --> [D], {memberchk(D, "0123456789")}.

您可以看到与原始规范的相似程度。接着就，随即

?- phrase(atom, "a").
true ;
false.

?- phrase(atom, "3a").
false.

?- phrase(atom, "a3").
true ;
false.

letter并digit展示匹配单个字符的不同方法。digit如果您需要从输入中捕获值，就像在您的代码中所做的那样，它会更简单。但是因为枚举 26*2 字符容易出错，请考虑使用code_type /2

atom(A) --> letter(L), atom_part(P), {A=[L|P]} | letter(L), {A=[L]}.
atom_part(P) --> letter(L), {P=[L]} | digit(D), {P=[D]} | letter(L), atom_part(A), {P=[L|A]} | digit(D), atom_part(A), {P=[D|A]}.
letter(L) --> [L], {code_type(L, alpha)}.
digit(D) --> [D], {memberchk(D, "0123456789")}.

还要考虑 Prolog 中的替代方案通常以这种方式编码

atom([L|P]) --> letter(L), atom_part(P).
atom([L]) --> letter(L).

更简单的形式允许在头部模式中移动“数据构造”。

于 2013-01-06T13:31:06.910 回答