5

这是 XPath 返回所有兄弟节点直到某个条件的常见请求的变体，由 Dimitre Novatchev 在XPath 轴上以特征完整性回答，获取所有以下节点，直到使用此模式：

$x/following-sibling::p
   [1 = count(preceding-sibling::node()[name() = name($x)][1] | $x)]

但这种模式依赖于 和 的对称性，依赖于following-sibling沿preceding-sibling轴在两个方向上观察的能力。

当轴为 时，是否有类似的模式ancestor-or-self？

例如：

<t>
  <a xml:base="/news/" >
    <b xml:base="reports/">
      <c xml:base="politics/" />
      <c xml:base="sports/" >
        <d xml:base="reports/" />
        <d xml:base="photos/" >
          <img url="A1.jpg" />
          <img url="A2.jpg" />
        </d>
      </c>
      <c xml:base="entertainment" />
    </b>
  </a>
</t>

直截了当

<xsl:template match="img">

    <xsl:for-each select="ancestor-or-self::*[@xml:base]">
        <xsl:value-of select="@xml:base"/>
    </xsl:for-each>

    <xsl:value-of select="@url"/>

</xsl:template>

会回来

 /news/reports/sports/photos/A1.jpg
 /news/reports/sports/photos/A1.jpg

但如果

      <c xml:base="sports/" >

相反

      <c xml:base="/sports/" >

有了那个引导/，for-each需要停止，以便返回

 /sports/photos/A1.jpg
 /sports/photos/A2.jpg

如何（在 XSLT/XPath 1.0 中）让它停止？

4

4 回答 4

3

这个 XSLT 1.0 转换：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pWanted" select="//img"/>
 <xsl:param name="pWantedAttr" select="'url'"/>

 <xsl:template match="/">
     <xsl:apply-templates select="$pWanted"/>
 </xsl:template>

 <xsl:template match="*[not(starts-with(@xml:base, '/'))]">
  <xsl:apply-templates select="ancestor::*[@xml:base][1]"/>
  <xsl:value-of select="concat(@xml:base,@*[name()=$pWantedAttr])"/>
  <xsl:if test="not(@xml:base)"><xsl:text>&#xA;</xsl:text></xsl:if>
 </xsl:template>

 <xsl:template match="*[starts-with(@xml:base, '/')]">
  <xsl:value-of select="@xml:base"/>
 </xsl:template>
</xsl:stylesheet>

应用于此 XML 文档时：

<t>
  <a xml:base="/news/" >
    <b xml:base="reports/">
      <c xml:base="politics/" />
      <c xml:base="/sports/" >
        <d xml:base="reports/" />
        <d xml:base="photos/" >
          <img url="A1.jpg" />
          <img url="A2.jpg" />
        </d>
      </c>
      <c xml:base="entertainment" />
    </b>
  </a>
</t>

产生想要的正确结果：

/sports/photos/A1.jpg
/sports/photos/A2.jpg

更新——单个 XPath 2.0 表达式解决方案：

   for $target in //img,
       $top in $target/ancestor::*[starts-with(@xml:base,'/')][1]
    return
      string-join(
         (
             $top/@xml:base
           , $top/descendant::*
                [@xml:base and . intersect $target/ancestor::*]
                   /@xml:base
           , $target/@url,
           '&#xA;'
        ),
        ''
                )

基于 XSLT 2.0 的验证：

<xsl:stylesheet version="2.0"   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="/">
     <xsl:sequence select=
      "for $target in //img,
           $top in $target/ancestor::*[starts-with(@xml:base,'/')][1]
        return
          string-join(
             (
                 $top/@xml:base
               , $top/descendant::*
                    [@xml:base and . intersect $target/ancestor::*]
                       /@xml:base
               , $target/@url,
               '&#xA;'
            ),
            ''
                    )
      "/>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<t>
  <a xml:base="/news/" >
    <b xml:base="reports/">
      <c xml:base="politics/" />
      <c xml:base="sports/" >
        <d xml:base="reports/" />
        <d xml:base="photos/" >
          <img url="A1.jpg" />
          <img url="A2.jpg" />
        </d>
      </c>
      <c xml:base="entertainment" />
    </b>
  </a>
</t>

对 XPath 表达式求值，并将该求值的结果复制到输出：

/news/reports/sports/photos/A1.jpg
 /news/reports/sports/photos/A2.jpg

使用修改后的文档：

<t>
  <a xml:base="/news/" >
    <b xml:base="reports/">
      <c xml:base="politics/" />
      <c xml:base="/sports/" >
        <d xml:base="reports/" />
        <d xml:base="photos/" >
          <img url="A1.jpg" />
          <img url="A2.jpg" />
        </d>
      </c>
      <c xml:base="entertainment" />
    </b>
  </a>
</t>

再次产生所需的正确结果：

/sports/photos/A1.jpg
 /sports/photos/A2.jpg

更新2：

OP 建议进行这种简化：

原始海报添加的更新：一旦嵌入到完整的应用程序中，完整的 url 替换了相对的，Dimitre 的方法最终变得如此简单

：

<xsl:template match="@url">
    <xsl:attribute name="url">
        <xsl:apply-templates mode="uri" select=".." />
        <xsl:value-of select="."/>
    </xsl:attribute>
</xsl:template>

<xsl:template match="*"  mode="uri">
    <xsl:if test="not(starts-with(@xml:base, '/'))">
        <xsl:apply-templates select="ancestor::*[@xml:base][1]" mode="uri"/>
    </xsl:if>
    <xsl:value-of select="@xml:base"/>
</xsl:template>
于 2013-01-05T02:47:30.803 回答
2

有一种方法可以在单个 for-each 选择表达式中选择正确的节点：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <xsl:template match="img">
    <xsl:for-each select="
      ancestor-or-self::*[
        starts-with(@xml:base, '/')
      ][1]/descendant-or-self::*[
        @xml:base and .//img[generate-id() = generate-id(current())]
      ]">
      <xsl:value-of select="@xml:base"/>
    </xsl:for-each>

    <xsl:value-of select="@url"/>
  </xsl:template>

</xsl:stylesheet>

鉴于此输入 XML：

<t>
  <a xml:base="/news/" >
    <b xml:base="reports/">
      <c xml:base="politics/" />
      <c xml:base="/sports/" >
        <d xml:base="reports/" />
        <d xml:base="photos/" >
          <img url="A1.jpg" />
          <img url="A2.jpg" />
        </d>
      </c>
      <c xml:base="entertainment" />
    </b>
  </a>
</t>

产生正确的结果：

/sports/photos/A1.jpg
/sports/photos/A2.jpg

XPath 表达式可以读作“从最近的@xml:base以斜杠开头的祖先开始，选择该祖先及其所有将当前<img>作为其后代之一的后代。”

这有效地选择了进入 XML 树的正确路径。

于 2013-01-05T08:47:14.357 回答
0

我找到了：在进入for-each循环之前计算满足条件的祖先。测试每个候选者以查看其条件匹配祖先的计数是否相同。

这个样式表

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    version="1.0">

    <xsl:template match="img">

        <xsl:variable name="distance" select="count(ancestor-or-self::*[@xml:base][substring(@xml:base,1,1)='/'])" />

        <xsl:for-each select="ancestor-or-self::*[@xml:base][
            count(ancestor-or-self::*[@xml:base][substring(@xml:base,1,1)='/'])=$distance
            ]">
                <xsl:value-of select="@xml:base"/>
        </xsl:for-each>

        <xsl:value-of select="@url"/>

    </xsl:template>

</xsl:stylesheet>

应用于给定的 XML

<t>
    <a xml:base="/news/" >
        <b xml:base="reports/">
            <c xml:base="politics/" />
            <c xml:base="/sports/" >
                <d xml:base="reports/" />
                <d xml:base="photos/" >
                    <img url="A1.jpg" />
                    <img url="A2.jpg" />
                </d>
            </c>
            <c xml:base="entertainment" />
        </b>
    </a>
</t>

返回所需的结果：

                /sports/photos/A1.jpg
                /sports/photos/A2.jpg

如果没有/before sports，for-each 会一直匹配祖先/news：

                /news/reports/sports/photos/A1.jpg
                /news/reports/sports/photos/A2.jpg
于 2013-01-05T02:51:05.527 回答
0

对原始模板稍作改动：

<xsl:template match="img">
    <xsl:for-each select="ancestor-or-self::*[@xml:base][not(.//*[starts-with(@xml:base, '/')])]">
         <xsl:value-of select="@xml:base"/>
    </xsl:for-each>
    <xsl:value-of select="@url"/>
</xsl:template>
于 2013-01-05T09:17:33.323 回答