1

在直接的 XSLT 1.0 中，不可能将字符串变量用作 XPath 表达式。

但是如果可能的表达式都很简单，比如“/book/chapter/verse”或“/year/make/model/style”——只有子轴，只有元素节点，没有谓词——是否有可能构建一个键该路径的关键字符串在哪里？就像是

<xsl:key name="elementByPath" match="*" use="path()" />

如果是这样，那么你可以

select=key(elementByPath, $var)

其中 $var 可以是像“/book/chapter/verse”这样的字符串。

但是直接的 XSLT 1.0 没有 path() 函数。:(

很容易找到一条路径

 <xsl:for-each select="ancestor-or-self::*">
      <xsl:text>/</xsl:text>
      <xsl:value-of select="name()"/>
 </xsl:for-each>

但这不能在@use 中使用。:(

当可能的表达式（尽管很多）很简单时，是否有另一种方法可以通过变量 XPath 表达式选择元素？

4

2 回答 2

1

或者如何递归解析字符串 brute-force：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
version="1.0">
<xsl:output omit-xml-declaration="yes" indent="yes"/>


<xsl:param name="pPath1" select="'books/book/title'"/>
<xsl:param name="pPath2" select="'books/book/description'"/>


<xsl:template match="/">
    <xsl:call-template name="elementsByPath">
        <xsl:with-param name="path" select="$pPath1" />
    </xsl:call-template>
    <xsl:text>==========&#xA;</xsl:text>
    <xsl:call-template name="elementsByPath">
        <xsl:with-param name="path" select="$pPath2" />
    </xsl:call-template>        
</xsl:template>


<xsl:template name="elementsByPath"> 
    <xsl:param name="path" />
    <xsl:choose>
        <xsl:when test="contains($path,'/')">
            <xsl:for-each select="*[name()=substring-before($path,'/')]"> 
                <xsl:call-template name="elementsByPath">
                    <xsl:with-param name="path" select="substring-after($path,'/')" />
                </xsl:call-template>
            </xsl:for-each>
        </xsl:when>
        <xsl:otherwise>
            <xsl:apply-templates select="*[name()=$path]" />
        </xsl:otherwise>
    </xsl:choose>
</xsl:template>

<xsl:template match="*">
    <xsl:copy-of select="." /><xsl:text>&#xA;</xsl:text>

</xsl:template>

</xsl:stylesheet>

当将该转换应用于 Dimitre 的示例 XML 时，将获得正确的结果：

<title>Extending Flash MX 2004</title>
<title>Java Software Solutions</title>
==========
<description>
        Using javascript alongwith actionscript 3.0 and mxml.
    </description>
<description>
        Complete book full of case studies on business solutions and design concepts while building mission critical
        business applications.
    </description>

我认为那会奏效。. .

于 2012-12-30T23:26:48.277 回答
1

可以做点什么：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:param name="pPath1" select="'/books/book/title'"/>
 <xsl:param name="pPath2" select="'/books/book/description'"/>

 <xsl:key name="kElemByPath" match="*"
  use="concat('/', name(ancestor-or-self::*[last()])
             ,'/', name(ancestor-or-self::*[last()-1])
             ,'/', name(ancestor-or-self::*[last()-2])
             )"/>

 <xsl:template match="/">
   <xsl:copy-of select="key('kElemByPath', $pPath1)"/>
==========&#xA;<xsl:text/>
   <xsl:copy-of select="key('kElemByPath', $pPath2)"/>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于以下 XML 文档时：

<books>
    <book isbn="1590593049">
        <title>Extending Flash MX 2004</title>
        <description>
        Using javascript alongwith actionscript 3.0 and mxml.</description>
    </book>
    <book isbn="0132149184">
        <title>Java Software Solutions</title>
        <description>
            Complete book full of case studies on business solutions and design concepts while building mission critical
            business applications.
        </description>
    </book>
</books>

产生了想要的正确结果：

<title>Extending Flash MX 2004</title>
<title>Java Software Solutions</title>
==========
<description>
        Using javascript alongwith actionscript 3.0 and mxml.</description>
<description>
            Complete book full of case studies on business solutions and design concepts while building mission critical
            business applications.
        </description>

如果您知道“路径”中的最大定位步骤数，则可以定义类似于此示例的键。位置步数较少的表达式必须以必要数量的斜杠结尾。

于 2012-12-30T23:04:13.790 回答