2

我的 TCustomControl 后代使用线程，这涉及使用 InvalidateRect 无效。我遇到过，当我在线程工作时关闭程序时，我不会停止 Destroy 中的线程，因为即使在我进入我的组件的 Destroy 的第一行之前（我通常在这里发出信号并等待线程停止工作），来自线程的代码使程序可能在句柄请求上显示异常“Control ... has no parent window”。

4

3 回答 3

4

所有的窗口交互——比如调用InvalidateRect——都应该在主线程中完成，所以将它从支持同步到主线程或摆脱额外的线程。

其次，当一个控件被销毁时，你不能再使用它的窗口句柄，因为它可能已经消失了。在这种情况下，VCL 将尝试重新创建句柄，尽管控件正在被破坏，从而导致各种错误。如果您显然或必须有可能在控件销毁期间调用的绘图指令，请在该代码周围进行检查：

if not (csDestroying in ComponentState) then

这段代码当然也必须在主线程中！（不是因为窗口句柄已经被销毁，而是因为 VCL 不是线程安全的）。这是暗示的，因为下面的代码 - 绘画 - （现在）也在主线程中。

于 2012-12-27T09:13:53.733 回答
1

这是从线程访问属性时的标准错误TWinControl.Handle- 在线程的上下文中重新创建底层窗口。

严格来说，TWinControl.Handle从线程访问是不安全的，尽管问题通常出现在某些极端情况下，例如关闭应用程序。

TWinControl类还提供受保护WindowHandle的属性。您可以在不强制创建窗口句柄的情况下读取该值。如果您从TWinControl（或TCustomControl）派生的组件提供对它的访问，则可以从线程访问它。

于 2012-12-27T08:28:19.760 回答
0

接受的答案仍然有意义，但我只是提供了一个可用于多线程和 VCL (TVCLMutex) 的对象，所以它部分回答了我自己的问题。诀窍是我在主线程中创建了另一个窗口，因此它共享相同的消息队列。从那时起，等待自己的消息使 VCL 神奇地安全，至少在大多数情况下是这样（因为所有代码都直接和间接来自同一个队列）。因此，如果您的线程想要访问/更改 VCL 中的某些内容，请创建 TVCLMutex 的单个实例并将不安全的访问代码包装在其 Access/Release 中，您可以确定主线程在 Windows 核心中的某个位置等待继续处理消息而无处可去别的。 

unit VclMutex;

interface uses Windows, Messages, SysUtils;

const
  WM_WaitInMainThread = WM_USER + 1;

type
  TVCLMutex = class
  private
    fVCLWaitEvent: THandle;
    fAccessAvailEvent: THandle;
    fWnd: HWnd;
    fThreadId: Cardinal;
    fLevel: integer;
  protected
    procedure   WndProc(var Msg: TMessage);
  public
    constructor Create;
    destructor  Destroy;override;
    procedure   Access;
    procedure   Release;
  end;

implementation uses Forms;

{ TVCLMutex }

constructor TVCLMutex.Create;
begin
  inherited Create;

  if GetCurrentThreadId <> MainThreadId then
    raise Exception.Create('The object should be created in the main thread');

  fWnd:=AllocateHWnd(WndProc);
  fVCLWaitEvent:=CreateEvent(Nil, false, false, Nil);
  fAccessAvailEvent:=CreateEvent(Nil, false, true, Nil); 
end;

destructor TVCLMutex.Destroy;
begin
  CloseHandle(fVCLWaitEvent);   
  CloseHandle(fAccessAvailEvent);

  DeallocateHWnd(fWnd);
  inherited;
end;

procedure TVCLMutex.WndProc(var Msg: TMessage);
begin
  case Msg.Msg of
    WM_WaitInMainThread:
      begin
           { ReplyMessage make return from SendMessage call called from other thread }
        ReplyMessage(0);

           { Waiting to release VCL (main thread) queure. Signal will come from the
             Release method of working thread  }
        WaitForSingleObject(fVCLWaitEvent, INFINITE);
      end
    else
      Msg.Result := DefWindowProc(FWnd, Msg.Msg, Msg.wParam, Msg.lParam);
  end;
end;

procedure TVCLMutex.Access;
var
  AThreadId: Cardinal;
begin
  AThreadId:=GetCurrentThreadId();

  if GetCurrentThreadId = fThreadId then
  begin
      { If owning thread then allow while keeping nested level }
    Inc(fLevel);
  end
  else
  begin
       { Waiting for section to be available (from other threads) }
    WaitForSingleObject(fAccessAvailEvent, INFINITE);

       { Owning thread }
    fThreadId:=AThreadId;

       { Ask main thread queue to wait }
    if fThreadId <> MainThreadId then
      SendMessage(fWnd, WM_WaitInMainThread, 0, 0);

    fLevel:=1;
  end
end;

procedure TVCLMutex.Release;
begin
  Dec(fLevel);

  if fLevel = 0 then { All nested releases passed  }
  begin
        { Signaling for queue to release (if different thread) }
    if fThreadId <> MainThreadId then
      SetEvent(fVCLWaitEvent);

    fThreadId:=0;
       { Signaling that the mutex section is available }
    SetEvent(fAccessAvailEvent);
  end;
end;

end.
于 2012-12-27T20:29:40.010 回答