prolog - 将小正则表达式转换为 DCG

Question

我知道 Prolog 程序员通常使用 DCG 而不是正则表达式来匹配字符串中的模式。在 Perl 中，可以写

if ( '... accd' =~ /a+b*c{2,4}d$/ ) {
    say "matched";
}

在 Prolog 中如何匹配相同的模式？

Answer 1

我已经扩展了这个答案

:- op(100, xf, *).
:- op(100, xf, +).

rexp(C) --> [C].

rexp([T|Ts])   --> rexp(T), rexp(Ts).
rexp([])       --> [].

rexp(eps)      --> [].

rexp(_*)       --> [].
rexp(R*)       --> rexp(R), rexp(R*).

rexp(R+)       --> rexp(R), rexp(R*).

rexp((R1|R2))  --> ( rexp(R1) ; rexp(R2) ).

rexp(range(R,N,M)) -->
    {between(N,M,L),
     length(D,L),
     maplist(copy_term(R),D)
    }, rexp(D).

那么你的正则表达式匹配可能是

?-  phrase(rexp([a+, b*, range(c,2,4), d]), [a,c,c,d]),
    writeln(matched).

请注意，通过这种方式我们匹配原子而不是单个字符。

在假'评论后编辑，我认为第一个条款应该是

rexp(C) --> {atomic(C)}, [C].

例如避免

?- phrase(rexp([a+]), [a+]).
true ;

事实上，在修正之后，我们得到了预期的结果：

?- phrase(rexp([a+]), [a+]).
false.

完成编辑

模式可以“硬编码”而不是解释正则表达式（更容易）

% I prefer the equivalent clause below
% p1 --> "a", p1 ; "a", p2.
p1 --> "a", (p1 ; p2).
p2 --> "b", p2 ; p3.
p3 --> ("cc" ; "ccc" ; "cccc"), "d".

然后

?- phrase(p1, "accd").
true

这里我们匹配单个字符（Prolog 中的字符串是字符代码列表）