1

我有一个可以替换一些 xml 值的 xsl 模板。现在我希望这些值由我的代码动态生成。

Transformer trans = TransformerFactory.newInstance().newTransformer(new StreamSource(new File("foo.xsl"));
trans.transform(new StreamSource(new File("foo.xml"), new StreamResult(new File("output.xml")));

我怎样才能获得例如仅在 id=1 的情况下替换名称？而且通过javacode动态提供该id，而不是硬编码？

<?xml version="1.0"?>
<my:accounts xmlns:my="http://myns">
<my:account>
<my:name>alex</my:name>
<my:id>1</my:id>
</my:account>
<my:account>
<my:name>Fiona</my:name>
<my:id>2</my:id>
</my:account>
</my:accounts>

这将替换所有名称：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:my="http://myns">

 <xsl:param name="propertyName" select="'alex'"/>

      <xsl:template match="node() | @*">
        <xsl:copy>
          <xsl:apply-templates select="node() | @*"/>
        </xsl:copy>
     </xsl:template>

<xsl:template match="*[local-name()='account']/*[local-name()='name']/text()[.='{$propertyName}']">
       <xsl:text>johndoe</xsl:text>
      </xsl:template>
    </xsl:stylesheet>
4

2 回答 2

2

这种转变：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:my="http://myns">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:param name="pId" select="2"/>

  <xsl:template match="node() | @*">
    <xsl:copy>
      <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
 </xsl:template>

 <xsl:template match="my:name/text()">
   <xsl:choose>
     <xsl:when test="../../my:id = $pId">johndoe</xsl:when>
     <xsl:otherwise><xsl:copy-of select="."/></xsl:otherwise>
   </xsl:choose>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<my:accounts xmlns:my="http://myns">
    <my:account>
        <my:name>alex</my:name>
        <my:id>1</my:id>
    </my:account>
    <my:account>
        <my:name>Fiona</my:name>
        <my:id>2</my:id>
    </my:account>
</my:accounts>

产生想要的正确结果：

<my:accounts xmlns:my="http://myns">
   <my:account>
      <my:name>alex</my:name>
      <my:id>1</my:id>
   </my:account>
   <my:account>
      <my:name>johndoe</my:name>
      <my:id>2</my:id>
   </my:account>
</my:accounts>

说明：

  1. 使用全局范围<xsl:param>。尽管设置了默认值，但它会被转换调用者指定的值覆盖。

  2. 请注意，如何为转换指定外部参数的值的问题对于不同的 xslt 处理器（供应商）有不同的答案。您需要阅读您使用的特定 XSLT 处理器的文档，以获得针对您的特定情况的答案。

于 2012-12-05T14:00:19.273 回答
0

您可以在 xsl 样式表中定义一个参数

<xsl:param name="id" select="'0'"/>

然后将其作为 Java 中的参数传递：

trans.setParameter("id", "1");

这对你有用吗？或者你想传递多个参数？

类似于这里提到的东西 - 变压器类

这个 xsl 有效，但它在 2.0 中

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:my="http://myns">
<xsl:param name="id" select="'1'"/>

  <xsl:template match="node() | @*">
    <xsl:copy>
      <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
 </xsl:template>

<xsl:template match="*[local-name()='account'][*:id=$id]/*[local-name()='name']/text()">
   <xsl:text>johndoe</xsl:text>
  </xsl:template>
</xsl:stylesheet>
于 2012-12-05T13:46:37.910 回答