3

我正在尝试设置动态打印范围以打印工作簿中的工作表，该工作簿是从同一工作簿中的另一张工作表填充的。我似乎遇到了麻烦。我在名称管理器中设置了一个名为横向的命名范围，如下所示：

=OFFSET('横向打印幻灯片'!$A$27, 0, 0, COUNTA('横向打印幻灯片'!$A:$A), COUNTA('横向打印幻灯片'!$1:$1))

我一直在尝试编写 VBA 代码（我对 VBA 一无所知）我有这个......

Sub Printarea()
    ActiveSheet.PageSetup.Printarea = "lateral"
End Sub

我收到错误“运行时错误'1004'”

任何人都可以帮忙吗？

4

1 回答 1

0

最后两个参数指定范围“横向”的高度和宽度。他们计算非空单元格的数量。像尼尔一样，我发现您的代码没有问题，前提是：

  • 您在 Slide Sheet Print Lateral 工作表上（否则对 Activesheet 的引用会出错，因为您试图将活动工作表的打印范围设置为不同工作表上的范围）；和
  • 幻灯片打印侧页的 A 列和第 1 行中有一些东西。但是，如果没有，您将为零范围指定高度和/或宽度。这是一个无效的范围引用，然后您将收到 1004 错误。

您可以安全地避免这种情况的唯一方法是在分配范围之前在 VBA 代码中获取 CountA 值；如果其中一个为零，则警告用户并中止。

我还建议您不要在此类过程中使用方法或属性名称；你通常可以侥幸逃脱，但有时它会导致问题。为了安全起见，调用类似 SetMyPrintRange 的过程。

编辑：经过反思，我不会费心检查计数；只是尝试获取对范围的引用，如果不能，然后告诉用户该怎么做。尝试这个：

Sub SetMyPrintArea()

    Dim l As Long
    Dim wks As Excel.Worksheet
    Dim rng As Excel.Range

    'Check that the worksheet exists.
    On Error Resume Next
    Set wks = ThisWorkbook.Worksheets("Slide Sheet Print Lateral")
    On Error GoTo ErrorHandler

    'If it doesn't, throw an error which will send it to the error handler.
    If wks Is Nothing Then
        Err.Raise vbObjectError + 20000, , _
         "The worksheet Slide Sheet Print Lateral is not in this workbook."
    End If

    'Try to get the reference to the range. If we can't, there's something wrong.
    On Error Resume Next
    Set rng = wks.Range("lateral")
    On Error GoTo ErrorHandler

    If rng Is Nothing Then
        Err.Raise vbObjectError + 20000, , _
         "Cannot find the range named 'lateral'. Please ensure that there is " _
         & "content in row 1 and column A of the Slide Sheet Lateral sheet."
    End If

    wks.PageSetup.Printarea = "lateral"

ExitPoint:

'Just cleaning up the object references
'to leave the place tidy...
On Error Resume Next
Set rng = Nothing
Set wks = Nothing
On Error GoTo 0

Exit Sub

ErrorHandler:

'Display the message and go to the exit point.
MsgBox "Error " & Err.Number & vbCrLf & Err.Description

Resume ExitPoint

End Sub
于 2012-11-26T10:38:03.090 回答