3

我有以下文件：

    20120127.221500.std|MT:63|ST:1.|ON:ABT.N|DRT:U|SEQ:862461707
      80 Bezahlt        : 55.04
      81 Bezahlt_Umsatz : 200
     281 Bezahlt_Zeit   : 22:00:02
     752 Quelle         : CTS OTC
      83 Umsatz_gesamt  : 5639295
     621 VWAP           : 54.984104
      26 Zeit           : 22:00:05

    20120127.232408.std|MT:63|ST:1.|ON:ABT.N|DRT:U|SEQ:862507497
      41 Schluss        : 55.02
     120 Schluss_Datum  : 27.01.2012

    20120128.011558.std|MT:63|ST:1.|ON:ABT.N|DRT:U|SEQ:862559511
      25 Datum          : 28.01.2012
      26 Zeit           : 01:01:30

我希望找到所有日期（即 27.01.2012、28.01.2012）并用今天的日期替换最新的日期（即 28.01.2012）。我希望用旧日期替换所有旧日期。我给你举个例子，因为我认为你最多能理解我。假设今天是 21.11.2012。我希望将 28.01.2012 替换为 21.11.2012，将 27.01.2012 替换为 20.11.2012。如果有 26.01.2012 我想用 19.11.2012 替换它。

任何人都可以给我线索我该怎么做？

也许一些提示算法应该是什么样子？我很想用 perl 来做。

我的问题是如何确定最早的日期。我从以下内容开始：

  open F ,"<$file";
    my $content = do{local $/;<F> };
    if ($content =~ /BOERSEN : [N|Q]/)
    {
      $content =~ /(\d\d\.\d\d\.\d\d\d\d)/;
      my $d = $1;
      my ($sec,$min,$hour,$mday,$mon,$year,$wday,$yday,$isdst) = localtime(time);
      $year+= 1900;
      $mon +=1;
      $mon = sprintf("%02d", $mon);
      $content =~ s/(\d\d)\.\d\d\.\d\d\d\d/$1\.$mon\.$year/msgi;
      my @d = split (/\./, $d);
      $d = $d[2].$d[1];
      $content =~ s/$d(\d\d)/$year$mon$1/msgi;
    }

但这并不是我真正想要的。

4

4 回答 4

3

我胡闹了一下，想出了这个。它需要先读取完整的输入，然后才能工作。

#!/usr/bin/perl
use strict; use warnings;
use DateTime;
use DateTime::Format::Strptime;

my $text = <<'TEXT';
foo 27.01.2012 27-01-2012
foo 28.01.2012 28-01-2012
foo 26.01.2012 26-01-2012
bar 10.07.2011 10-07-2011
TEXT

# Formatter to make DateTime objects
my $strp = DateTime::Format::Strptime->new(
    pattern   => '%d.%m.%Y',
);
my $today = DateTime->today; # we need that to calculate

# Get all the dates from the input and turn them into DateTime objects
my %dates = map { $_ => $strp->parse_datetime($_) }
    $text =~ m/(\d{2}\.\d{2}.\d{4})/gm;

# Determine the latest date (the one nearest to today) and clone it
my $max_date = (sort { DateTime->compare( @dates{$a, $b} ) } keys %dates )[-1];
$max_date = $dates{$max_date}->clone;

foreach my $date ( keys %dates ) {
    # The new value needs to have the same "distance" to today as the old one
    # had to the highest date from the input

    # Do that calculation and format it
    my $new_date = $strp->format_datetime(
        $today - ($max_date - $dates{$date}));
    # Needs \Q and \E because there are '.' in the date
    $text =~ s/\Q$date\E/$new_date/g;
}

这是输出：

foo 22.11.2012 27-01-2012
foo 23.11.2012 28-01-2012
foo 21.11.2012 26-01-2012
bar 05.05.2012 10-07-2011
于 2012-11-23T17:01:12.143 回答
2

该Time::Piece模块满足此目的，它是核心模块，因此不需要安装。

该程序获取当前日期和时间，然后通过将其格式化为%d.%m.%Y字符串并将其读回，将时间字段设置为零。然后它打开并读取日志文件，查看所有日期并找到最新的日期。计算文件中的最新日期与当前日期之间的差值，并将文件倒回到开头并再次读取。这一次，每个日期都添加了计算出的增量，并在输出中替换了字符串。

use strict;
use warnings;

use Time::Piece ();
use Fcntl ':seek';

my $today = Time::Piece->new;
$today = Time::Piece->strptime($today->dmy('.'), '%d.%m.%Y');

open my $fh, '<', 'logfile.txt' or die $!;

my $latest = 0;

while (<$fh>) {
  if ( /:\s*(\d\d\.\d\d\.\d\d\d\d)/ ) {
    my $date = Time::Piece->strptime($1, '%d.%m.%Y');
    $latest = $date if $date > $latest;
  }
}

my $delta = $today - $latest;
seek $fh, 0, SEEK_SET;

while (<$fh>) {

  s{:\s*\K(\d\d\.\d\d\.\d\d\d\d)}{
    my $date = Time::Piece->strptime($1, '%d.%m.%Y');
    $date += $delta;
    $date->dmy('.');
  }eg;

  print;
}

输出

20120127.221500.std|MT:63|ST:1.|ON:ABT.N|DRT:U|SEQ:862461707
  80 Bezahlt        : 55.04
  81 Bezahlt_Umsatz : 200
 281 Bezahlt_Zeit   : 22:00:02
 752 Quelle         : CTS OTC
  83 Umsatz_gesamt  : 5639295
 621 VWAP           : 54.984104
  26 Zeit           : 22:00:05

20120127.232408.std|MT:63|ST:1.|ON:ABT.N|DRT:U|SEQ:862507497
  41 Schluss        : 55.02
 120 Schluss_Datum  : 22.11.2012

20120128.011558.std|MT:63|ST:1.|ON:ABT.N|DRT:U|SEQ:862559511
  25 Datum          : 23.11.2012
  26 Zeit           : 01:01:30
于 2012-11-23T22:24:34.930 回答
2

CPAN上有很多日期和时间模块。

您将需要找到一个可以轻松地将 N 天添加到日期的人。mktime使用和strftime来自POSIX模块和strptime来自POSIX::strptime模块可能就足够了。

您需要通过指定要成为当前日期的“旧日期”来确定 N。您以天为单位计算两个日期（旧日期和当前日期）之间的差异，给您一个整数值 N。然后对于每个日期行，提取日期部分，添加 N 天，并重写日期部分与新的假日期。

您询问确定“最古老”的日期。您显示的格式基于 ISO 8601，这意味着可以将诸如 20120127 之类的字符串排序为字符串或数字以给出日期顺序。您似乎也有一个日志文件；在此类文件中，第一个日期通常是最旧的，最后一个日期是最新的，因为它们是按单调递增的时间顺序顺序写入的。

于 2012-11-23T16:27:31.243 回答
1

以下是操作文件的一些指针：

open F ,"<$file";
my $content = do{local $/;<F> };
close(F);

my $DATE_RE = qr/((\dd)\.(\d\d)\.(\d\d\d\d))/;
my %jdate;
# Find all of the dates and convert them to date ordinals
while ($content =~ m/$DATE_RE/g) {
  $jdate{$1} ||= jdate($2, $3, $4);
}

# find the most recent date
my $latest;
for my $d (keys %jdate) {
  if (!$latest || $jdate{$latest} < $jdate{$d}) {
    $latest = $d
  }
}

# for each date $d, determine what to replace it with
my %replacement;
for my $d (keys %jdate) {
  $replacement{$d} = ...your code here...
}

# Replace all of the dates
$content =~ s/$DATE_RE/$replacement{$1}/ge;

# done!

关键是jdate(...)将日-月-年转换为整数的函数。CPAN 上有很多模块可以做到这一点 - 例如Time::JulianDay。

要确定日期替换，您可以使用inverse_julian_day()将儒略日序数转换为日-月-年三元组的函数，例如：

my ($y, $m, $d) = inverse_julian_day( $today_jd - ($jdate{$latest} - $jdate{$d}) );
$replacement{$d} = sprintf("%02d.%02d.%04", $d, $m, $y);
于 2012-11-23T17:11:06.510 回答