3

看看我的语法

grammar protocol;

options {  
  language = Java; 
  output = AST;
}                     
//imaginary tokens
tokens{ 
BOOL;
CHAR;
STRING;
}
parse
    : declaration
    ;

declaration
    :   variable
    ;
variable
    :   locals
    ;
locals
  :  (bool
  |  char
  |  string)+
  ;
bool
    :'bool' ID -> ^(BOOL ID)
    ;
char
    : 'char' ID -> ^(CHAR ID)
    ;
string  
    :'string' ID -> ^(STRING ID)
    ;

ID  
    : (('a'..'z' | 'A'..'Z'|'_')('a'..'z' | 'A'..'Z'|'0'..'9'|'_'))*
    ;
INT 
    : ('0'..'9')+
    ;
WHITESPACE
    : ('\t' | ' ' | '\r' | '\n' | '\u000C')+ {$channel = HIDDEN;}
    ;

对于以下输入，

bool boolVariable
char charVariable
string stringVariable

我的语法创建了以下 AST
AST 对于变量的语法

我不能多次声明一个变量。我不想一次声明相同类型的变量，用逗号分隔，但我想要这样

bool boolVariable1
bool boolVariable2
bool boolVariable3
string stringVariable1
string stringVariable2

这样做之后，我希望所有变量都属于两种主要类型。共享和本地。在 Java 中，共享变量（静态）是对所有对象具有单个副本的变量，而局部变量对每个对象具有单独的副本。我希望用户在定义变量集之前明确指定变量的范围。喜欢，

locals:
    bool boolVariable1
    bool boolVariable2
    bool boolVariable3
    string stringVariable1
    string stringVariable2
shared:
    bool boolVariable4
    bool boolVariable5
    bool boolVariable6
    string stringVariable3
    string stringVariable4
    char charVariable1

此外，有什么方法可以检查用户不能有两个同名的变量吗？喜欢，

bool boolVariable
bool boolVariable

应该给出某种错误或类似的错误。有什么想法/帮助吗？
谢谢

编辑 - 解决方案

grammar protocol;

options {  
  language = Java; 
  output = AST;
}                     
//imaginary tokens
tokens{ 
BOOL;
CHAR;
STRING;
SBOOL;
SCHAR;
SSTRING;
}
parse
    : declaration
    ;

declaration
    :   variable
    ;
variable
    :   (locals 
    |   shared)*
    ;
locals
  : 'locals:' (bool| char| string)*
  ;
bool
    :'bool' ID -> ^(BOOL ID)
    ;
char
    : 'char' ID -> ^(CHAR ID)
    ;
string  
    :'string' ID -> ^(STRING ID)
    ;
shared
  : 'shared:' (sbool| schar| sstring)*
  ;

sbool
    :'bool' ID -> ^(SBOOL ID)
    ;
schar
    : 'char' ID -> ^(SCHAR ID)
    ;
sstring 
    :'string' ID -> ^(SSTRING ID)
    ;
ID  
    : (('a'..'z' | 'A'..'Z'|'_')('a'..'z' | 'A'..'Z'|'0'..'9'|'_'))*
    ;
INT 
    : ('0'..'9')+
    ;
WHITESPACE
    : ('\t' | ' ' | '\r' | '\n' | '\u000C')+ {$channel = HIDDEN;}
    ;
4

2 回答 2

1

正如 Bahdan 在他的回答中提到的那样，您需要维护一个已经使用过的名称的集合。这是一个基于您更新的语法的简单示例（在此答案的底部进行了一些其他更改）。新规则var是使用新成员代码的地方。请注意，这里没有进行真正的错误处理，只是进行名称检查。

grammar protocol;

options {  
  language = Java; 
  output = AST;
}                     
//imaginary tokens
tokens{ 
BOOL;
CHAR;
STRING;
SBOOL;
SCHAR;
SSTRING;
}

@parser::header { 
    import java.util.ArrayList;
}

@members {
    private ArrayList<String> variableNames = new ArrayList<String>();

    private boolean variableDefined(String name){
        return variableNames.contains(name);
    }

    private void defineVariable(String name){
        variableNames.add(name);
    }
}

parse
    : declaration
    ;

declaration
    :   variable
    ;
variable
    :   (locals | shared)*
    ;
locals
    : 'locals:' (bool| char_ | string)*
    ;
bool
    :'bool' var -> ^(BOOL var)
    ;
char_
    : 'char' var -> ^(CHAR var)
    ;
string  
    :'string' var -> ^(STRING var)
    ;
shared
    : 'shared:' (sbool| schar| sstring)*
    ;
sbool
    :'bool' var -> ^(SBOOL var)
    ;
schar
    : 'char' var -> ^(SCHAR var)
    ;
sstring 
    :'string' var -> ^(SSTRING var)
    ;   
var
    : ID 
      {!variableDefined($ID.text)}? //This rule is only satisfied if the variable is new. 
      {defineVariable($ID.text);}  //we made it here, so it's new. Add it for future reference.
    ;    
ID  
    : ('a'..'z' | 'A'..'Z'|'_')('a'..'z' | 'A'..'Z'|'0'..'9'|'_')*
    ;
INT 
    : ('0'..'9')+
    ;
WHITESPACE
    : ('\t' | ' ' | '\r' | '\n' | '\u000C')+ {$channel = HIDDEN;}
    ;

我可以声明两个变量，如 bool boolVariable bool boolVariable 但我不能声明两个变量，如 bool boolVariable bool boolVariable12

请参阅我对ID上面的更改。有一组额外的括号破坏了规则。我还重命名char为char_让解析器为我正确编译。

于 2012-11-19T22:26:29.153 回答
1

你可以试试这个：

  locals
      :  bool* char* string*
      ;

它应该允许您声明具有相同类型的不同变量。禁止声明具有相同名称的不同变量的最佳（我认为）方法是将集合（在 Java 中）与声明的先前变量保持一致。只需调用 Java 函数，就像这里

最诚挚的问候

于 2012-11-19T13:18:19.863 回答