19

谁能帮我创建一个批处理文件？基本上，我的目标是创建一个批处理文件，将最新的 7 个 .txt 文件（换句话说，最新的）保存在文件夹中，然后删除其余文件。那是如果文件夹中有超过 7 个文件。

我现在遇到的问题是，我创建的批处理文件删除了大部分文件，因为它们的日期是一两个月左右。我想始终保留最新的 7 个文件，无论它们有多旧。

所以这就是我所拥有的 -

@echo off

setlocal enableextensions

rem ********************************************************************************
rem *******************************  LOCAL VARIABLES  ******************************
rem ********************************************************************************

SET TargetDirectory="C:\TEMP\test"

SET No_of_fles_to_keep=7

SET count=0 

set cnt=0

rem ********************************************************************************

cd /d %TargetDirectory%

REM timeout /T 500

 for %%x in (*) do set /a count+=1

 for %%A in (*.bat) do set /a cnt+=1

cd /d %TargetDirectory%

REM timeout /T 500

IF %count% gtr %No_of_fles_to_keep% forfiles -p %TargetDirectory% -s -m "*.txt" -d -%No_of_fles_to_keep% -c "cmd /c del @path"

echo %count% 

echo File count = %cnt%

任何帮助表示赞赏。

4

3 回答 3

33

您可以使用 DIR with/O-D按时间戳降序列出文本文件。FOR /F 允许您遍历每个文件。SET /A 用于跟踪到目前为止列出了多少文件。现在是棘手的部分。

在代码块中，您通常需要使用延迟扩展来处理之前在同一块中设置的变量的值。!但是，如果 FOR 变量值包含, 并且!在文件名中有效，则延迟扩展可能会导致 FOR 循环出现问题。我通过在读取第 7 个文件名时使用 SET /A 故意除以 0 来解决此问题。这会引发一个错误，导致执行未定义 KEEP 变量的条件代码。从那时起，所有剩余的文件都将被删除。

@echo off
setlocal
set /a cnt=0
set "keep=7"
for /f "eol=: delims=" %%F in ('dir /b /o-d /a-d *.txt') do (
  if defined keep (
    2>nul set /a "cnt+=1, 1/(keep-cnt)" || set "keep="
  ) else del "%%F"
)

更新

哦，天哪，我刚刚意识到有一个简单的解决方案。只需使用 FOR /F SKIP 选项在按最后修改日期降序排序后忽略前 7 个条目。

for /f "skip=7 eol=: delims=" %%F in ('dir /b /o-d /a-d *.txt') do @del "%%F"

您甚至不需要批处理文件。只需更改%%为%if 从命令提示符运行。

于 2012-11-13T20:17:34.513 回答
2

下面的批处理文件使用了一种更简单的方法。它使用findstr /N "^"命令对每个文件进行编号，然后仅比较每个编号以保留前七个文件并删除其余文件...

@echo off
for /f "tokens=1* delims=:" %%a in ('dir /b /o-d *.txt ^| findstr /N "^"') do (
   if %%a gtr 7 del "%%b"
)

安东尼奥

于 2012-11-13T22:49:47.233 回答
-2

这将保留 7 个最新的 .txt 文件并删除所有其他 .txt 文件

在要从中删除文件的同一目录中执行以下命令

在命令提示符下

for /f "skip=7 eol=: delims=" %F in ('dir /b /o-d /a-d *.txt') do @del "%F"

内部批处理脚本

for /f "skip=7 eol=: delims=" %%F in ('dir /b /o-d /a-d *.txt') do @del "%%F"
于 2017-07-06T13:08:52.313 回答