delphi - 是否有将圆的度数移动到 0 的功能？

Question

我正在 Delphi XE2 中的某处寻找一个函数，类似于Inc()它允许我从当前度数中添加/减去多个度数并产生新度数。例如，如果我目前有一个点在一个圆周围 5 度，我想减去 10，我不应该得到 -5 度，而是 355 (360 - 5)。与添加过去的 360 相同 - 当它达到 360 时它应该回到 0。

Delphi中是否已经有类似的东西所以我不必重新编写它？也许在Math单位？

Answer 1

uses
  System.SysUtils,Math;

Function WrapAngle( angle : Double) : Double;
Const
  modAngle : Double = 360.0;
begin
  Result := angle - modAngle*Floor(angle/modAngle);
end;

begin
  WriteLn(FloatToStr(WrapAngle(-5)));
  WriteLn(FloatToStr(WrapAngle(5-720)));
  WriteLn(FloatToStr(WrapAngle(360)));
  ReadLn;    
end.

产生结果：

355
5 
0

更新：

正如@Giel 发现的那样，在 XE3 中有一个新功能DegNormalize()可以完成这项工作。甚至快 25% 左右。诀窍是将Floor()调用替换为Int()，如果结果是否定的，则添加modAngle到结果中。

Answer 2

function WrapAngle(Value: Integer): Integer;
begin
  Result := Value mod 360;
  if Result < 0 then
    Inc(Result, 360);
end;

Answer 3

我用来执行此任务的代码是：

function PosFrac(x: Double): Double;
(* PosFrac(1.2)=0.2 and PosFrac(-1.2)=0.8. *)
begin
  Result := Frac(x); (* Frac(x)=x-Int(x) *)
  if Result<0.0 then begin
    Result := 1.0+Result;
  end;
end;

function ModR(const x, y: Double): Double;
(* ModR(1.2,1)=0.2 and ModR(-1.2,1)=0.8 *)
var
  absy: Double;
begin
  if y=0.0 then begin
    Result := 0.0;
  end else begin
    absy := abs(y);
    Result := PosFrac(x/absy)*absy;
  end;
end;

function Mod360(const x: Double): Double;
begin
  Result := ModR(x, 360.0);
end;

此代码会将所有角度带入到 的范围0内360。例如：

Writeln(Round(Mod360(5-10)));
Writeln(Round(Mod360(5-360)));
Writeln(Round(Mod360(5-720)));
Writeln(Round(Mod360(5+720)));

输出：

355
5
5
5

Answer 4

我不知道，但无论如何我更喜欢使用更通用的解决方案......

Procedure IncOverFlow(var Value:Double;Difference:Double;Limit:Double=360);
begin
   Value := Value + Difference;
   While Value < 0 do Value := Value + Limit;
   While Value >= Limit do Value := Value -Limit;
end;

Answer 5

procedure WrapAngle(var Degs: Integer);
begin
  Degs := Degs mod 360;
  if Degs < 0 then
    Inc(Degs, 360);
end;