3

我正在对来自 Tcl8.6 和 Rivet 的 TclOO 进行一些试验，但我遇到了麻烦，因为我无法做我想做的事。

使用文件中的以下代码可以简单地重现该问题.rvt：

<?

proc dumbproc {} {
    puts "this is dumbproc ([namespace current])"
}

oo::class create foo {
    method bar {} {
        puts "this is bar ([namespace current])"
        dumbproc
    }
}

set obj [foo new]

dumbproc

$obj bar

如果我只是看一下代码，它似乎应该按预期工作，但实际上并没有，因为 Rivet 包的微妙行为和选择的特定配置。

在此示例中，我使用了一个.rvt文件，其代码在::request命名空间内执行，因此该dumbproc过程的完全限定名称是::request::dumbproc. 当在方法内部调用名称解析算法时bar，它先搜索dumbprocinside ::oo::Obj12，然后搜索 in ::oo，最后搜索 in ::，但没有找到并给出以下错误。

this is dumbproc (::request) this is bar (::oo::Obj16)

invalid command name "dumbproc"
    while executing
"dumbproc"
    (class "::request::foo" method "bar" line 3)
    invoked from within
"$obj bar"
    (in namespace eval "::request" script line 21)
    invoked from within
"namespace eval request {
puts -nonewline ""


    proc dumbproc {} {
        puts "this is dumbproc ([namespace current])"
    }

    oo::class create..."

所以，Tcl做它所做的事情是正确的，那就是一个特性。但是这种行为是不可预测的，因为当你编写一些类代码时，你必须知道它将被使用的上下文。

事实上，如果我放弃启动<?Rivet 魔法，将代码放在test.tcl文件中并在交互式会话中使用它，我会得到同样的错误：

$ tclsh
% namespace eval ::myns {source test.tcl}
this is dumbproc (::myns)
this is bar (::oo::Obj12)
invalid command name "dumbproc"

我试图通过将当前命名空间添加到类创建代码来解决这个问题

::oo::class create [namespace current]::foo { ... }

然后，我还尝试obj在命名空间内创建对象

::oo::class create [namespace current]::foo { ... }
namespace eval [namespace current] {set obj [[namespace current]::foo new]}

然后，我切换到create类的方法，为对象提供一个包含命名空间的限定名称

foo create [namespace current]::obj
obj bar

但一切都没有成功。每次试验都表明，无论我怎么做，TclOO 类中的方法总是在其对象唯一命名空间内执行。我错了吗？

有没有办法得到我想要的？TclOO 是否不打算以这种方式工作，在这种情况下为什么呢？真正让我惊讶的是这种依赖于上下文的行为，我不确定这是不是正确的事情，但也许我完全错了，并且有一些合理的案例，我错过了。

4

1 回答 1

5

每个 TclOO 对象的内部实际上是它自己的命名空间。您可以在您的方法中使用self namespaceor来获取命名空间的名称，或者从任何地方获取命名空间。默认情况下放置在命名空间中的唯一命令是（用于调用私有方法），并且其他命名空间中的某些命令通过标准 Tcl机制可用（这是您获取和可用的方式）。namespace currentinfo object namespace $theobjmynamespace pathselfnext

解决此问题的最简单方法可能是将其添加到foo类的构造函数中：

namespace path [list {*}[namespace path] ::request]

在您的特定情况下，您必须实际添加一个构造函数......

constructor {} {
    namespace path [list {*}[namespace path] ::request]
    # If you had a non-trivial constructor in a superclass, you'd need to call
    # [next] too.
}

从长远来看，要求一种机制来添加名称空间列表可能是合理的，这些名称空间用于为类的对象设置默认值。如果您愿意，请提交功能请求……</p>

[编辑]：如果您只是在将父命名空间添加到当前对象的命令解析路径之后，您可以通过添加更多魔法来做到这一点：

oo::class create foo {
    self {
        method create args {
            set ns [uplevel 1 {namespace current}]
            next {*}[linsert $args 1 $ns]
        }
        method new args {
            set ns [uplevel 1 {namespace current}]
            next {*}[linsert $args 0 $ns]
        }
    }
    constructor {creatorNS args} {
        namespace path [list {*}[namespace path] $creatorNS]
    }
    method bar {} {
        puts "this is bar ([namespace current])"
        dumbproc
    }
}

然后，这将自动将当前命名空间置于实例路径上。如果您在许多类中这样做，您可能希望创建一个包含大部分机器的元类，但上述技术（在类对象本身上self 声明一些方法foo）适用于简单的情况。

于 2012-11-08T11:24:27.853 回答