3

如果我定义一个新类，我可以使用 Indy 命令 TIdThreadSafe 使类 MyPrivateClass 线程安全吗

   MyNewIndyClass = Class(TIdThreadSafe)
         FLocal :  MyPrivateClass 
         create
          ......
          end;

我的 MyPrivateClass 不是线程安全的，因为我在这个类中访问 TList 和 TBitmap 项

如果我将 TCPServer.Onexecute 代码更改为以下样式

    ......

     aNewIndyClass  :=  MyNewIndyClass.Create; 

     aNewIndyClass.FLocal.CallFuntionA; 

     aNewIndyClass.FLocal.CallFuntionB; 

      ......

这种方法的想法：保持 MyPrivateClass 代码不变，只需在单独的类中添加对 Indy Server onexecute 的请求

4

1 回答 1

3

You should use Lock() and Unlock() methods of TIdThreadSafe class. For example in TCPServer.OnExecute() call aNewIndyClass's methods like this:

  aNewIndyClass  :=  MyNewIndyClass.Create; 

  aNewIndyClass.Lock;   // This will enter TIdThreadSafe internal's Critical Section object
  try
    with aNewIndyClass do  // The code between try/finally will be "atomic"
    begin                  // i.e. no other thread will be able to do anything with your object
      ...
      FLocal.CallFuntionA; 
      FLocal.CallFuntionB; 
      ...
    end;
  finally                 // The use of TRY/FINALLY is MANDATORY when working with critical sections!
    aNewIndyClass.Unlock; // This will leave the CS
  end;

Also it's better to use properties (i.e. getter/setter) for accessing private or protected members of your MyNewIndyClass class.

By the way if you are using Delphi 2009 and newer you can get advantage of Generics. A short example implementation of a generic thread safe class may be:

  tThreadSafeObject<T: class> = class
    private
      fObject: T;
      fCriticalSection: tCriticalSection;
    public
      constructor Create(cpObject: T);  // We expect previously created object here. We own it!
                                        // TODO: Implement ownership option?
      destructor Destroy;
      function Lock: T;
      procedure Unlock;
  end;

{ tThreadSafe<T> }

constructor tThreadSafeObject<T>.Create(cpObject: T);
begin
  inherited Create;
  fObject := cpObject;
  fCriticalSection := TCriticalSection.Create;
end;

destructor tThreadSafeObject<T>.Destroy;
begin
  FreeAndNil(fObject);  // In this sample implementation fObject is owned so we free it
  FreeAndNil(fCriticalSection);
  inherited Destroy;
end;

function tThreadSafeObject<T>.Lock: T;
begin
  fCriticalSection.Enter;
  result := fObject;
end;

procedure tThreadSafeObject<T>.Unlock;
begin
  fCriticalSection.Leave;
end;

Usage:

procedure foo;
var 
  tsObj: tThreadSafeObject<tMyClass>;
begin
 tsObj := tThreadSafeObject<tMyClass>.Create(tMyClass.Create);
 try      // In real World tsObj would be variable, accessed by different threads
   with tsObj.Lock do
   try
     // Do some atomic stuff here
   finally
     tsObj.Unlock;
   end;
 finally
   freeAndNil(tsObj);
 end 
end;
于 2012-10-28T23:12:54.277 回答