1

我正在从 xml 文件中检索数据并将其存储在文本文件中。以下是 my.xml 文件：

<?xml version="1.0"?>
<Parent>
<Action>POSTACTION</ActionState>
<Message><![CDATA[An Exception is thrown testFunctionAlpha()]]></Message>
<Property key="Direction"  value="IN"/>
<Property key="MethodName"  value="testFunctionAlpha"/>
<Property key="ReturnValue"  value="exception"/>
</Parent>

<Parent>
<Action>PREACTION</ActionState>
<Message><![CDATA[This is message of myFunction ]]></Message>
<Property key="Direction"  value="IN"/>
<Property key="MethodName"  value="myFunction"/>
<Property key="ReturnValue"  value="cmy::returnvalue"/>
</Parent>

xml 文件中有多个这样的记录。我正在使用以下命令来解析这个 xml 并将日期存储在测试文件中。

xsltproc scan.xsl my.xml >> output.txt

以下是用于解析 xml 文件的 scan.xsl 文件内容：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
  <xsl:output method="text"/>
<xsl:template match="Parent">
<xsl:variable name="mesg" select="./Message"/>
<xsl:if test="$mesg = 'An Exception is thrown testFunctionAlpha()'">
  <xsl:value-of select="./Action"/><xsl:text> </xsl:text>
  <xsl:value-of select="$mesg"/><xsl:text> </xsl:text>
  <xsl:apply-templates select="Property[@key='Direction']"/><xsl:text> </xsl:text>
  <xsl:apply-templates select="Property[@key='MethodName']"/><xsl:text> </xsl:text>
  <xsl:apply-templates select="Property[@key='ReturnValue']"/>
</xsl:if>
</xsl:template>

  <xsl:template match="Property"><xsl:value-of select="@value"/></xsl:template>

</xsl:stylesheet>

我想将日期存储在文本文件中，只有那些具有标签值的标签是“抛出异常 testFunctionAlpha()”我可以使用上面的代码得到这个，但是 Output.txt 包含， - 不匹配的空行标签。如何避免空行？因此 output.txt 仅包含与 xsl 格式匹配的数据。

4

1 回答 1

2

如果您确保在第一个模板上捕获根元素，则可以确保不应用内置的默认处理模板，然后仅将模板应用于您想要映射的元素。

此外，换行符的另一个来源可能是如果您的任何text()s 中有额外的空格，您可以使用该normalize-space()函数在您的xsl:selects

由于您的示例输入 xml 无效，因此我添加了一个包装器根元素 (xml) 并将ActionResult结束标记更改为Action.

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
    <xsl:output method="text"/>
    <xsl:template match="/xml">
        <xsl:apply-templates select="Parent"/>
    </xsl:template>

    <xsl:template match="Parent">
        <xsl:variable name="mesg" select="Message"/>
        <xsl:if test="$mesg = 'An Exception is thrown testFunctionAlpha()'">
            <xsl:value-of select="Action"/>
            <xsl:text> </xsl:text>
            <xsl:value-of select="$mesg"/>
            <xsl:text> </xsl:text>
            <xsl:apply-templates select="Property[@key='Direction']"/>
            <xsl:text> </xsl:text>
            <xsl:apply-templates select="Property[@key='MethodName']"/>
            <xsl:text> </xsl:text>
            <xsl:apply-templates select="Property[@key='ReturnValue']"/>
        </xsl:if>
    </xsl:template>

    <xsl:template match="Property">
        <xsl:value-of select="@value"/>
    </xsl:template>

</xsl:stylesheet>

输入 XML：

<xml>
    <Parent>
        <Action>POSTACTION</Action>
        <Message><![CDATA[An Exception is thrown testFunctionAlpha()]]></Message>
        <Property key="Direction"  value="IN"/>
        <Property key="MethodName"  value="testFunctionAlpha"/>
        <Property key="ReturnValue"  value="exception"/>
    </Parent>

    <Parent>
        <Action>PREACTION</Action>
        <Message><![CDATA[This is message of myFunction ]]></Message>
        <Property key="Direction"  value="IN"/>
        <Property key="MethodName"  value="myFunction"/>
        <Property key="ReturnValue"  value="cmy::returnvalue"/>
    </Parent>
</xml>

结果：

POSTACTION 抛出异常 testFunctionAlpha() IN testFunctionAlpha 异常

编辑

如果您不想捕获根，您也可以text()通过抑制它来覆盖内置模板：

<xsl:template match="text()"/>
于 2012-10-09T08:01:17.763 回答