8

我意识到以下是一个坏主意，原因有很多。我还意识到，鉴于我的 stackoverflow 代表为 23，因此很自然地假设我是一个学习编程的新手。但是，请幽默我，并专注于“我们如何做到这一点”而不是“你为什么要这样做/你不想这样做”方面。

我想要的是：

(def dog (Dog. ...))
(def cat (Cat. ...))

(with-animal dog
  (println (str "Dog: " (speak) "\n")))
(with-animal cat
  (println (str "Cat: " (speak) "\n")))

输出：

Dog: woof
Cat: meow

所以基本上，我希望with-animal成为一个宏，所有出现的“speak”函数调用都映射到我正在调用块的对象。

特别是，我不想写：

(let-binding [speak (fn [] "woof")] ...)
(let-binding [speak (fn [] "meow")] ...)

相反，我希望 with-animal 将speak函数映射到我正在调用的对象的某个方法。

在 Clojure 中有没有一种干净的方法可以做到这一点？

谢谢！

4

2 回答 2

20

动态绑定的存在是有原因的，它有很多很好的用途，所以不用担心因为试图理解它而被激怒:-) 在许多旧的 Clojure 教程中存在一些混淆，这些教程早于添加 ^:dynamic 元数据的需要到您希望动态重新绑定的变量。

第一个示例通过重新绑定现有名称来使用动态绑定。这消除了宏引入新符号的需要：

首先制作一些动物，我在这个例子中只是使用地图，很多人会使用一些其他类型的对象：

(def dog {:sound #(str "wooooof")})
(def cat {:sound #(str "mewwww")})

将我们将要重新绑定的函数定义为动态的（允许重新绑定）

(defn :^dynamic speak [] (println "eh?"))

编写一个基本的模板宏来绑定动物中的函数：

(defmacro with-animal [animal & body] 
    `(binding [speak (:sound ~animal)] 
       ~@body))

并测试它：

(with-animal dog  
  (println (str "Dog: " (speak) "\n")))
Dog: wooooof

现在是“高级版本”，它只是speak使用 let 将符号引入范围，而不需要动态绑定。这并不是说绑定在某些方面不好，它只是更符合你不写的愿望。(let-binding [speak (fn [] "meow")] ...)这种类型的 maco 称为照应（如果你喜欢这样花哨的名字）：

重要的部分是显式将非限定符号引入范围~'的符号之前：speak

user> (defmacro with-animal [animal & body]
    `(let [~'speak (:sound ~animal)] 
        ~@body))
#'user/with-animal

user> (with-animal dog 
        (println (str "Dog: " (speak) "\n")))
Dog: wooooof 

nil

我希望这两个示例之间的对比有助于回答您关于将行为从对象绑定到范围的问题。第一个示例绑定了 maco 主体的值以及从该主体调用的任何内容。第二个示例只为宏的主体引入名称。

于 2012-10-08T21:46:53.797 回答
0

如果您真的想让动物类型说话惯用，请使用 Clojure 协议：

(defprotocol ISpeak
  (speak [animal] "make the type say it's thing"))

(deftype Dog []
  ISpeak
  (speak [this] "Woof!"))

(deftype Cat []
  ISpeak
  (speak [_] "Meow!!")) ;;you can "drop" the item if not used using _

(def a-dog (Dog.))
(speak a-dog)
;;=>"Woof!"

(def a-cat (Cat.))
(speak a-cat)
;;=>"Meow!!"

请注意，您可以使用 speak 方法扩展任何类型（类）。

(extend java.util.Random
  ISpeak
  {:speak (fn [_] "I'm throwing dices at you!")})

(speak (java.util.Random.))
;;=>"I'm throwing dices at you!"

Java 类的语法略有不同，请参阅协议文档以获取更多信息。

于 2015-07-17T15:09:50.920 回答