6

如果我们在 Perl 中不关闭文件会有多严重？如果我在同一个程序中再次访问它会影响程序或文件吗？

4

3 回答 3

13

全局文件句柄将一直存在，直到您的程序退出。这可能很糟糕，但是由于您可能无论如何都不应该使用全局文件句柄，因此这不是问题。

当它们的范围离开/它们的引用计数下降到零时，带有 d 的my词法文件句柄。close

如果重新使用文件句柄的名称，则前一个文件句柄是closed 隐含的。以下脚本重用相同的文件句柄来打印任意数量文件的前五行：

my $fh;
foreach my $filename (@ARGV) {
  open $fh, "<", $filename or die "Can't open $filename";  # $fh is re-used
  print scalar <$fh> // next for 1 .. 5;                   # // is the defined-or
}

处理文件时，明确关闭 FH 并不重要。但是，在进行 IPC 时，这一点至关重要。关闭管道的写入端表示读取端的 EOF。

ing时fork，应关闭所有未使用的文件句柄，因为它们在分叉时会重复。这意味着在一个进程中关闭管道可能不会发送所需的 EOF，因为同一管道在相关进程中仍处于打开状态。

这是一个演示closeIPC 重要性的程序：

pipe my $out, my $in or die $!;

if (fork()) {  # PARENT
  close $out;                            # close unused handle    (important!)
  select $in;
  $| = 1;                                # set $in to autoflushed (important!)
  $SIG{PIPE} = sub {die "Parent"};       # die, when the pipe is closed
  print ++$i, "\n" and sleep 1 while 1;  # print one number per second
} else {       # CHILD
  close $in;                             # close unused handle
  print scalar <$out> for 1 .. 5;        # read numbers 1 to 5 from the pipe
  close $out;                            # close the pipe (and trigger SIGPIPE)
  sleep 5;                               # wait, then exit
  die "Child";
}

该程序的输出是数字 1 到 5。然后子进程关闭管道，SIGPIPE在父进程中触发。当父母死亡时，孩子会在周围徘徊 5 秒钟，直到它也死去。

这是有效的，因为父级关闭了管道的读取端。如果close $out从父级中删除，则SIGPIPE不会被触发，并且程序会无限打印数字。

于 2012-10-03T08:57:10.523 回答
2

如果您不关闭文件，您的程序可能会用完可用的文件描述符。

人perlfunc：

close
           Closes the file or pipe associated with the filehandle, flushes the IO 
           buffers, and closes the system file descriptor.
于 2012-10-03T06:23:18.230 回答
1

一些输出错误可能会延迟到文件关闭。因此，关闭文件并检查返回值通常是一个好习惯。如在

# open (my $fd, ">", $fname) somewhere upstream
close $fd 
    or die "Couldn't finish writing to $fname: $!";

除此之外，程序将在退出时愉快地关闭全局文件句柄，并在它们离开范围时关闭词法文件句柄。

于 2012-10-03T06:48:58.493 回答