0

切割相当于 dos 没有在 for 循环中工作

week_date.txt 的内容 

18092012                                                                        
19092012                                                                        
20092012                                                                        
21092012                                                                        
22092012                                                                        
23092012                                                                        
24092012

我正在运行批处理脚本并在以下部分面临变量值替换问题

for /f %%I in (weekly_date.txt) do ( 

echo %%I
set yy=%%I:~4,4%
set mm=%%I:~2,2%
set dd=%%I:~0,2%

echo %yy%

SET bp=/xx/yy/%mm%/%dd%
SET br=/aa/bb/%mm%/%dd%
SET TP=F:\xx\%yy%\%mm%\%dd%\yy

echo %bp%
echo %br%
echo %TP% )

done

==================================================== =======================
然后在 

SET bp=/xx/yy/%/%mm%/%dd%
SET br=/aa/bb/%/%mm%/%dd%
SET TP=F:\xx\%yy%\%mm%\%dd%\ff

运行批处理脚本时，它以下列方式被替换 

SET bp=/xx/yy/%i:~2,2/%i:~0,2  
SET br=/aa/bb/%i:~2,2/%i:~0,2  
SET TP=F:\xx\%i:~4,4\%i:~2,2\%i:~0,2\ff

实际上输出必须是

/xx/yy/09/18 /aa/bb/09/18 F:\xx\2012\09\18\ff

/xx/yy/09/19 /aa/bb/09/19 F:\xx\2012\09\19\ff

…………

/xx/yy/09/24 /aa/bb/09/24 F:\xx\2012\09\24\ff

任何人都可以指出我哪里出错了吗？

在此先感谢

4

1 回答 1

0

对于您的代码，我将进行两个主要更改：1）将 for 循环的输入设置为另一个变量（称为 var）以进行操作 2）启用延迟扩展，这允许在每次 for 循环迭代时操作变量。让我知道是否需要对我的代码进行任何其他更改 =]

我的代码如下：

@echo off
setLocal EnableDelayedExpansion

for /f %%I in (weekly_date.txt) do ( 
set var=%%I
set yy=!var:~4,4!
set mm=!var:~2,2!
set dd=!var:~0,2!

set bp=/xx/yy/!mm!/!dd!
set br=/aa/bb/!mm!/!dd!
set TP=F:\xx\!yy!\!mm!\!dd!\ff

echo !bp! !br! !TP!
)

endlocal

使用您提供的相同的 week_dates.txt 输入，此代码的输出为：

/xx/yy/09/18 /aa/bb/09/18 F:\xx\2012\09\18\ff 
/xx/yy/09/19 /aa/bb/09/19 F:\xx\2012\09\19\ff 
/xx/yy/09/20 /aa/bb/09/20 F:\xx\2012\09\20\ff 
/xx/yy/09/21 /aa/bb/09/21 F:\xx\2012\09\21\ff 
/xx/yy/09/22 /aa/bb/09/22 F:\xx\2012\09\22\ff 
/xx/yy/09/23 /aa/bb/09/23 F:\xx\2012\09\23\ff 
/xx/yy/09/24 /aa/bb/09/24 F:\xx\2012\09\24\ff
于 2012-10-01T20:32:52.407 回答