7

这真让我抓狂。我想对列和变量进行简单的比较，但它不起作用。以下行总是计算所有元组，而我只需要那些受 where 子句限制的元组。

 SELECT count(*) INTO cnt from class where class.fid = fid;

它看起来很简单，但我已经为此工作了几个小时。完整的 sql 过程是

令人困惑的是，如果我用一些硬编码的 ID（如 105）替换 fid，它会给出正确的答案），但是当我使用 fid 时，它就不再起作用并返回所有类的计数。出于某种原因，总是 class.fid = fid。当我使用 >、< 或 <> 时，返回 0 个计数！

create or replace PROCEDURE pro_report2
AS
CURSOR c_dept IS select deptid, dname from department;
TYPE cur_typ IS REF CURSOR;
c1 cur_typ;
query_str1 VARCHAR2(200);
fid faculty.fid%type := 102;
fname faculty.fname%type;
cnt NUMBER;

BEGIN
    FOR dept_row in c_dept LOOP
        DBMS_OUTPUT.PUT_LINE('Dept.Name: ' || dept_row.dname);
        DBMS_OUTPUT.PUT_LINE('Faculty Name' || chr(9)|| chr(9) || '0 Class' || chr(9) || chr(9) || '1 Class' || chr(9) || chr(9) || '2 Classes' || chr(9) || '>2 Classes');
        DBMS_OUTPUT.PUT_LINE('-------------------------------------------------------------------------------');
        --find all faculty in this department
        query_str1 := 'select fid, fname from faculty where faculty.deptid = ' || to_char(dept_row.deptid);
        open c1 for query_str1;
        LOOP
            FETCH c1 into fid, fname;
            exit when c1%notfound;
            DBMS_OUTPUT.PUT_LINE(fname);
            SELECT count(*) INTO cnt from class where class.fid = fid;
            DBMS_OUTPUT.PUT_LINE(to_char(cnt) || '    ' || to_char(fid));
        END LOOP;
        -- Spaces between departments
        DBMS_OUTPUT.PUT_LINE(chr(10));
        DBMS_OUTPUT.PUT_LINE(chr(10));
    END LOOP;
END;

谢谢

4

1 回答 1

7

我相信您需要重命名或为本地变量添加前缀fid，因为不幸的是它与您正在查询的表中的列名匹配。SQL 引擎只是fid = fid对每一行进行比较，这将始终是正确的（空值除外，但这是另一回事）。另外，当变量名称与列相同时，更难阅读代码。

在 PL/SQL 中，往往有一个约定，用 a l_(for local) 作为局部变量的前缀，所以很清楚目的是什么。但是，除列名之外的任何名称都可以。尝试：

l_fid faculty.fid%type := 102;

进而...

SELECT count(*) INTO cnt from class where class.fid = l_fid;

（加上其他适当的替代品。）

于 2012-09-30T18:12:26.980 回答