14

我正在使用nasm编译以下程序集。但是，代码在 Windows 下的控制台中崩溃。

C:\>nasm -f win32 test.asm -o test.o

C:\>ld test.o -o test.exe

section .data
  msg   db    'Hello world!', 0AH
  len   equ   $-msg

section .text
  global _WinMain@16

_WinMain@16:
  mov   edx, len
  mov   ecx, msg
  mov   ebx, 1
  mov   eax, 4
  int   80h

  mov   ebx, 0
  mov   eax, 1
  int   80h

根据这个帖子。该main功能在 Windows 下不可用，必须替换为WinMain.

因此，如果您的入口点是_start或main，则应将其更改为并将过程末尾的_WinMain@16更改为：retret 16

我的工作示例：

section .text       
 global _WinMain@16       

_WinMain@16:       
 mov eax, 0       
 ret 16
4

2 回答 2

35

最大的问题是你试图在 Windows 上使用 Linux 中断！int 80 在 Windows 上不起作用。

我们正在使用 Assembly，因此您的入口点可以是您想要的任何标签。ld 寻找的标准入口点是 _start，如果你想使用另一个标签，你需要用 -e 选项告诉 ld 所以如果你想让你的开始标签是 main，那么你需要

global main
ld -e main test.o -o test.exe

如果你打算在 Windows 上使用 NASM，我会推荐使用 GoLink 作为你的链接器。这是一个简单的 Windows 控制台应用程序：

STD_OUTPUT_HANDLE   equ -11
NULL                equ 0

global GobleyGook
extern ExitProcess, GetStdHandle, WriteConsoleA

section .data
msg                 db "Hello World!", 13, 10, 0
msg.len             equ $ - msg

section .bss
dummy               resd 1

section .text
GobleyGook:
    push    STD_OUTPUT_HANDLE
    call    GetStdHandle

    push    NULL
    push    dummy
    push    msg.len
    push    msg
    push    eax
    call    WriteConsoleA 

    push    NULL
    call    ExitProcess

生成文件：

hello: hello.obj
    GoLink.exe  /console /entry GobleyGook hello.obj kernel32.dll  

hello.obj: hello.asm
    nasm -f win32 hello.asm -o hello.obj
于 2012-09-25T01:24:40.817 回答
9

虽然，同样的程序可能会像魅力一样在 Linux 上的 WINE 中运行。:)

WINE 不会阻止在 Windows PE 二进制文件中使用 Linux 系统调用；机器指令本机运行，WINE 仅提供 DLL 函数。

于 2013-02-05T21:19:19.337 回答