2

我有两个模块：test1 和 test2，我需要依次运行它们的子程序。他们需要修改相同的变量 $var 并且外部脚本需要打印最终结果。不幸的是，这不起作用，并且似乎与此SO Question非常相似。

#test1.pm
use strict;
package test1;
my $var;
sub step1 {
  $var = "Hello";
}
1;

#test2.pm
use strict;
package test2;
my $var;
sub step1 {
    $var = $var." World!\n";
}
1;

#execTests.pl
use strict;
require test1;
require test2;
&test1::step1;
&test2::step1;
print $test2::var;

如何使 $var 包含在两个必需包的相同范围内？

4

3 回答 3

1

AFAIK不可能有两个变量总是共享相同的值。以下是一些可以帮助您的想法：

包变量：

{
   package test1;
   our $var;
   sub step1 {$var = "Hello"}
}
{
  package test2;
  our $var;
  sub step1 {$var .= " World!\n"}
}

test1::step1();
$test2::var = $test1::var;
test2::step1();

print $test2::var;

评语：丑

参考：

{
  package test1;
  our $varref;
  sub init {
    my ($ref) = @_;
    $varref = $ref;
  }
  sub step1 {$$varref = "Hello"}
}
{
  package test2;
  our $varref;
  sub init {
    my ($ref) = @_;
    $varref = $ref;
  }
  sub step1 {$$varref .= " World!\n"}
}

my $var = "";
test1::init(\$var);
test2::init(\$var);

test1::step1();
test2::step1();

print $var;

评论：更好，但需要更多代码。

一个额外的共享模块：

{
  package test::shared;
  our $var;
}
{
  package test1;
  sub step1 {$test::shared::var = "Hello"}
}
{
  package test2;
  sub step1 {$test::shared::var .= " World!\n"}
}

test1::step1();
test2::step2();
print $test::shared::var;

评论：有一些优点。

显式状态

{
  package test1;
  sub step1 {
    my $state = @_;
    $state->{var} = "Hello";
    return $state;  # superfluous, but helps understanding
  }
}
{
  package test2;
  sub step1 {
    my $state = @_;
    $state->{var} .= " World!\n";
    return $state;  # superfluous, but helps understanding
  }
}

my $state = {};

$state = test1::step1($state);  # equiv: test1::step1($state), because of references
$state = test2::step1($state);

print $state->{var};

评论：这几乎是面向对象的编程。我更喜欢这种模式，因为它明确说明了何时给出共享。在多线程和重入方面，显式状态可以轻松扩展您的应用程序。

成本：明确性。冗长的语法。

好处：可重入，通过明确性清晰思路。

于 2012-09-20T17:59:43.930 回答
1

有了明显的免责声明，即这是BAD BAD BAD DESIGN，您可以简单地使用 glob：

==> exec.pl <==
#!/usr/bin/perl
use strict;
use warnings;
# You can omit this line, but there will be a warning about $My::Var being used only once
$My::Var = undef;
require 's1.pl';
require 's2.pl';
print $My::Var . "\n";

==> s1.pl <==
$My::Var = "Hello";


==> s2.pl <==
$My::Var .= "World";

Glob 基本上是包存储中的条目。包变量和子程序存在于包存储中；存储条目称为 glob。

http://perldoc.perl.org/perlguts.html#Stashes-and-Globs

stash 和 glob 的相对简单性以及操作它们的容易性是我认为 Perl 非常酷的原因之一。

于 2012-09-20T18:33:07.557 回答
1

主要问题是声明的变量my不是包变量，不能通过使用包名完全限定它来访问。但是，即使您通过 using 声明包变量our，您仍然可以使用test1.pm并execTests,pl引用$test1::varwhiletest2.pm正在使用$test2::var

我建议您改用主程序本地的变量，并将其传递给两个步骤进行修改

像这样的东西（测试和工作）

测试1.pm

use strict;
use warnings;

package test1;

use parent 'Exporter';
our @EXPORT = qw/step1/;

sub step1 {
  $_[0] = "Hello";
}

1;

测试2.pm

use strict;
use warnings;

package test2;

use parent 'Exporter';
our @EXPORT = qw/step2/;

sub step2 {
    $_[0] .= " World!\n";
}

1;

执行测试.pl

use strict;
use warnings;

use test1;
use test2;

my $var;

step1($var);
step2($var);

print $var;

输出

Hello World!
于 2012-09-20T20:07:20.720 回答