假设我在 sql server 2008 中有以下 sql 语句：
BEGIN TRANSACTION
SqlStatement1
EXEC sp1
SqlStatement3
COMMIT TRANSACTION
sp1的代码
BEGIN TRANSACTION
SqlStatement2
ROLLBACK TRANSACTION
我的问题是：SqlStatement3真的被执行了吗？
问问题
36176 次
5 回答
34
SQL Server 并不真正支持嵌套事务。一次只有一笔交易。
这一事务有一个基本的嵌套事务计数器，@@TRANCOUNT. 每次连续begin transaction将计数器加一，每次commit transaction将其减一。只有将commit计数器减少到 0 的才会真正提交一个事务。
Arollback transaction撤消一个事务并清除@@TRANCOUNT。
在您的情况下，有趣的结果是 SqlStatement3在事务之外运行！您的 finalcommit将抛出“COMMIT TRANSACTION 请求没有相应的 BEGIN TRANSACTION”异常，但 SqlStatement3 的影响是永久的。
例如：
create table #t (col1 int)
insert #t (col1) values (1)
BEGIN TRANSACTION
update #t set col1 = 2 -- This gets rolled back
BEGIN TRANSACTION
update #t set col1 = 3 -- This gets rolled back too
ROLLBACK TRANSACTION
update #t set col1 = 4 -- This is run OUTSIDE a transaction!
COMMIT TRANSACTION -- Throws error
select col1 from #t
打印4。真的。:)
于 2012-09-17T09:50:57.563 回答
18
您可以使用事务保存点。sp1 可以使用错误处理和嵌套事务中描述的模式：
create procedure [usp_my_procedure_name]
as
begin
set nocount on;
declare @trancount int;
set @trancount = @@trancount;
begin try
if @trancount = 0
begin transaction
else
save transaction usp_my_procedure_name;
-- Do the actual work here
lbexit:
if @trancount = 0
commit;
end try
begin catch
declare @error int, @message varchar(4000), @xstate int;
select @error = ERROR_NUMBER(), @message = ERROR_MESSAGE(), @xstate = XACT_STATE();
if @xstate = -1
rollback;
if @xstate = 1 and @trancount = 0
rollback
if @xstate = 1 and @trancount > 0
rollback transaction usp_my_procedure_name;
raiserror ('usp_my_procedure_name: %d: %s', 16, 1, @error, @message) ;
end catch
end
这种模式允许在 sp1 中完成的工作回滚，但保持包含事务的活动。
于 2012-09-17T11:56:43.463 回答
5
Rollback transaction它自己回滚所有事务。
http://msdn.microsoft.com/en-us/library/ms181299(v=sql.100).aspx
该语句仍将执行 - 试试这个
create table #t (i int)
insert #t values (1) -- t contains (1)
begin tran
update #t set i = i +1
select * from #t -- t contains (2)
begin tran
update #t set i = i +1
select * from #t -- t contains (3)
rollback tran -- transaction is rolled back
select * from #t -- t contains (1)
update #t set i = i +1
select * from #t -- t contains (2)
commit -- error occurs
select * from #t -- t contains (2)
drop table #t
于 2012-09-17T09:37:43.123 回答
5
可以使用嵌套事务。要仅回滚内部事务，请使用保存点并回滚到保存点。如果内部事务无论是否嵌套，IF都可以使用语句来确定是否设置保存点以及是否回滚或回滚到保存点：
BEGIN TRAN
DECLARE @WILL_BE_NESTED_TRANSACTION BIT = CASE WHEN (@@TRANCOUNT > 0) THEN 1 ELSE 0 END
IF @WILL_BE_NESTED_TRANSACTION = 1
SAVE TRAN tran_save
BEGIN TRAN
-- do stuff
IF @WILL_BE_NESTED_TRANSACTION = 1
ROLLBACK TRAN tran_save
ELSE
ROLLBACK
ROLLBACK
于 2017-02-08T08:39:24.793 回答
4
SQL Server 数据库引擎会忽略提交内部事务。基于在最外层事务结束时采取的操作，事务要么被提交，要么被回滚。如果提交了外部事务，则也提交了内部嵌套事务。如果外部事务被回滚，那么所有内部事务也会被回滚，而不管内部事务是否被单独提交。
于 2016-11-09T12:06:55.913 回答