3

我对在Mathematica中标记绘图有疑问。我将描述我的问题。

我有这样的功能。

y = 4 x / L + 2

我想绘制 y 与 x 的关系图。而且，我有

L={10,20,30,40}

当我编写如下代码时，

Plot[y, {x, 0, 100}, 
    ImageSize -> Scaled[1.0], PlotLabel ->  Style["y vs X ", FontSize -> 18]]

我在同一张图中有四个不同的图。我想知道如何用相关的 L 值标记每个图。

4

2 回答 2

4

根据我之前的帖子，您可以使用此方法随意标记线条。标记后，可以发现没有动态内容的情节设置为plainplot。

它通过将每一行变成一个自标记按钮来工作。您可以labels针对不同的标签进行修改。

l = {10, 20, 30, 40};
y[x_, s_] := 4 x/s + 2

plot = Plot[Evaluate@Table[y[x, u], {u, l}], {x, 0, 100},
   PlotLabel -> Style["y vs X ", FontSize -> 18]];

pos = Position[plot, _Line];
Array[(line[#] = plot[[Sequence @@ pos[[#]]]]) &, Length@l];
AddLabel[label_] := Module[{},
  AppendTo[plot[[1]], Inset[Framed[label, Background -> White], pt]];
  (* Removing buttons for final plot *)
  plainplot = plot;
  Array[
   (plainplot[[Sequence @@ pos[[#]]]] =
      plainplot[[Sequence @@ Append[pos[[#]], 1]]]) &, Length@l]]
labels = ToString /@ l;
Array[
  (plot[[Sequence @@ pos[[#]]]] =
     Button[line[#], AddLabel[labels[[#]]]]) &, Length@l];
Dynamic[EventHandler[plot,
  "MouseDown" :> (pt = MousePosition["Graphics"])]]

在此处输入图像描述

于 2012-09-14T19:11:43.710 回答
3 
l = {10, 20, 30, 40}
y[x_, s_] := 4 x/s + 2
<< PlotLegends`

Plot[Evaluate@Table[y[x, u], {u, l}], {x, 0, 100}, 
 ImageSize -> Scaled[1.0], 
 PlotLabel -> Style["y vs X ", FontSize -> 18], 
 PlotLegend -> ("L = " <> ToString@# & /@ l)]

数学图形

于 2012-09-14T14:57:34.340 回答