delphi - TLoginCredentialService 使用示例

Question

这个新类的文档页面（在 XE2 中引入）仅包含对 TObject 文档或占位符的引用。我可以看到这个类提供了一个 RegisterLoginHandler 方法和一个 UnRegisterLoginHandler 方法，它们使用了一个TLoginCredentialEvent类。这使用带有用户名和密码的TLoginEvent对象。

这个类的典型用例会是什么样子（源代码）？它是否在 Delphi Datasnap/Web 服务库的某个地方使用？

Answer 1

我刚刚创建了一个如何使用它的小演示

点击这里下载代码

下面我将展示一些代码：

首先，我需要一个记录来保存凭证，以及它们的列表：

Type
  TCredential = record
    Username, Password, Domain: string;
    constructor Create(const aUsername, aPassword, aDomain: string);
    function AreEqual(const aUsername, aPassword, aDomain: string): Boolean;
  end;

  TCredentialList = class(TList<TCredential>)
  public
    function IsValidCredential(const aUsername, aPassword, aDomain: string): Boolean;
  end;

然后我们需要定义一个我们称之为的上下文。那只是一个应用程序唯一的字符串，用于标识每个登录功能

const
  Context = 'TForm1';

在表单创建中，我创建我的列表并向其中添加虚拟数据

procedure TForm1.FormCreate(Sender: TObject);
begin
  CredentialList := TCredentialList.Create;
  //Add Dummy data
  CredentialList.Add(TCredential.Create('AA', 'AA', 'DomainAA'));
  CredentialList.Add(TCredential.Create('BB', 'BB', 'DomainAA'));
  CredentialList.Add(TCredential.Create('CC', 'CC', 'DomainAA'));

  // Register your Login handler in a context.
  // This method is called when you try to login
  // by caling TLoginCredentialService.GetLoginCredentials();
  TLoginCredentialService.RegisterLoginHandler(Context, LoginCredentialEvent);
end;

我在我的表单上放置了一个按钮，我打电话给 login ：

procedure TForm1.Button1Click(Sender: TObject);
begin
  // The actual call to login
  // First param is the context
  // Second Parameres is a callback function given to the event handler.
  TLoginCredentialService.GetLoginCredentials(Context,
    function { LoginFunc } (const Username, Password, Domain: string): Boolean
    begin
      //The actual user validation
      Result := CredentialList.IsValidCredential(Username, Password, Domain);
    end);
end;

最后我只需要实现我的登录处理程序：

//This is the "onLogin" event handler.
//This is called durring a login attempt
//The purpose of this event handler are to call tha callBack function with correct information
//and handle the result
procedure TForm1.LoginCredentialEvent(Sender: TObject; Callback: TLoginCredentialService.TLoginEvent; var Success: Boolean);
begin
  //Call the callback
  Callback(Sender, LabeledEdit1.Text, LabeledEdit2.Text, LabeledEdit3.Text, Success);

  //Handle the success.
  if Success then
    Label1.Caption := 'Yes'
  else
    Label1.Caption := 'No';
end;

希望这能回答问题。不要忘记在此处下载完整代码