0

我正在尝试使用 ANTLR 创建表达式解析器 该表达式将进入 if 语句，因此它的根是一个条件。

我有以下语法，它“编译”到解析器/词法分析器文件没有问题，但是生成的代码本身有一些错误，本质上是两个“空”的 if 语句，即 if (())

不知道我做错了什么，任何帮助将不胜感激。

谢谢。

语法.g文件如下：语法表达式；

options {
  language=CSharp3;
  output=AST;
}

tokens {
  ROOT;
  UNARY_MIN;
}

@parser::namespace { Antlr3 }
@lexer::namespace { Antlr3 }
public parse
  :  orcond EOF -> ^(ROOT orcond)
  ;

orcond
  :  andcond ('||' andcond)*
  ;

andcond
  :  condition ('&&' condition)*
  ;

condition
  :  exp (('<' | '>' | '==' | '!=' | '<=' | '>=')^ exp)?
  ;

exp
  :  addExp
  ;

addExp
  :  mulExp (('+' | '-')^ mulExp)*
  ;

mulExp
  :  unaryExp (('*' | '/')^ unaryExp)*
  ;

unaryExp
  :  '-' atom -> ^(UNARY_MIN atom)
  |  atom
  ;

atom
  :  Number
  |  '(' parenthesisvalid ')' -> parenthesisvalid
  ;

parenthesisvalid
  :  fullobjectref
  |  orcond
  ;

fullobjectref
  :  objectref ('.' objectref)?
  ;

objectref
  :  objectname ('()' | '(' params ')' | '[' params ']')?
  ;

objectname
  :  (('a'..'z') | ('A'..'Z'))^ (('a'..'z') | ('A'..'Z') | ('0'..'9') | '_')*
  ;

params
  :  paramitem (',' paramitem)?
  ;

paramitem
  :  unaryExp
  ;

Number
  :  ('0'..'9')+ ('.' ('0'..'9')+)?
  ;

Space 
  :  (' ' | '\t' | '\r' | '\n'){Skip();}
  ;
4

2 回答 2

2

不要..在解析器规则中使用范围运算符 , 。

删除解析器规则objectname并创建词法分析器规则：

Objectname
  :  ('a'..'z' | 'A'..'Z') ('a'..'z' | 'A'..'Z' | '0'..'9' | '_')*
  ;
于 2012-09-09T19:29:46.487 回答
0

此外，使用片段块将更加整洁。在这种情况下，您的代码将是这样的：

Objectname  :  LETTER (LETTER  | DIGIT | '_')*;    
Number: DIGIT+ ('.' DIGIT+)?;
fragment DIGIT : '0'..'9' ;
fragment LETTER : ('a'..'z' | 'A'..'Z');
于 2012-09-20T06:46:45.617 回答