xml - XML 使用 XSL 合并节点内的同名元素

Question

我有以下xml

<EMPLS>
 <EMPL>
    <NAME>110</NAME>
    <REMARK>R1</REMARK>
  </EMPL>
 <EMPL>
    <NAME>111</NAME>
    <REMARK>R1</REMARK>
    <REMARK>R2</REMARK>
    <REMARK>R3</REMARK>
  </EMPL>
</EMPLS>

并且需要将xml转换为以下格式：

<EMPLS>
 <EMPL>
    <NAME>110</NAME>
    <REMARK>R1</REMARK>
  </EMPL>
 <EMPL>
    <NAME>111</NAME>
    <REMARK>R1 R2 R3</REMARK>
  </EMPL>
</EMPLS>

我是 xsl 的新手，请您告知如何完成。

Answer 1

我这个 XSLT 1.0 转换：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:key name="kChildByName" match="EMPL/*"
  use="concat(generate-id(..), '+', name())"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

  <xsl:template match="EMPL/*" priority="0"/>

 <xsl:template match=
 "EMPL/*
     [generate-id()
     =
      generate-id(key('kChildByName',
                       concat(generate-id(..), '+', name())
                      )[1]
                  )
      ]">
  <xsl:copy>
   <xsl:for-each select="key('kChildByName',
                             concat(generate-id(..), '+', name())
                         )">
    <xsl:if test="not(position()=1)"><xsl:text> </xsl:text></xsl:if>
    <xsl:value-of select="."/>
   </xsl:for-each>
  </xsl:copy>
 </xsl:template>
 <xsl:template match="EMPL/*" priority="0"/>
</xsl:stylesheet>

当应用于提供的 XML 文档时（已从众多畸形中纠正）：

<EMPLS>
 <EMPL>
    <NAME>110</NAME>
    <REMARK>R1</REMARK>
  </EMPL>
 <EMPL>
    <NAME>111</NAME>
    <REMARK>R1</REMARK>
    <REMARK>R2</REMARK>
    <REMARK>R3</REMARK>
  </EMPL>
</EMPLS>

产生想要的正确结果：

<EMPLS>
   <EMPL>
      <NAME>110</NAME>
      <REMARK>R1</REMARK>
   </EMPL>
   <EMPL>
      <NAME>111</NAME>
      <REMARK>R1 R2 R3</REMARK>
   </EMPL>
</EMPLS>

说明：

1. 正确使用和覆盖身份规则。

2. 正确使用Muenchian 分组方法和复合键。

---

二、XSLT 2.0 解决方案：

<xsl:stylesheet version="2.0"   xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output omit-xml-declaration="yes" indent="yes"/>

 <xsl:template match="node()|@*">
     <xsl:copy>
       <xsl:apply-templates select="node()|@*"/>
     </xsl:copy>
 </xsl:template>

 <xsl:template match="EMPL">
  <xsl:copy>
    <xsl:for-each-group select="*" group-by="name()">
     <xsl:copy>
       <xsl:value-of select="current-group()" separator=" "/>
     </xsl:copy>
    </xsl:for-each-group>
  </xsl:copy>
 </xsl:template>
</xsl:stylesheet>

说明：

1. 正确使用<xsl:for-each-group>.

2. 正确使用current-group()功能。