1

我在使用 XSLT 重命名 xml 标记时遇到问题。下面是我的输入xml。

原始 XML：

<soapenv:Envelope xmlns:soapenv="http://www.w3.org/2003/05/soap-envelope">
<soapenv:Body>
<ns:Response xmlns:ns="http://demo.test.classes.com">
   <ns:return>
      <ns:person>
         <ns:personName></ns:personName>
         <ns:personAge></ns:personAge>
         <ns:personAddress>
            <ns:addressType>official</ns:addressType>
            <ns:addressLine1>official address line 1</ns:addressLine1>
         </ns:personAddress>
         <ns:personAddress>
            <ns:addressType>residence</ns:addressType>
            <ns:addressLine1>residence address line 1</ns:addressLine1>
         </ns:personAddress>         
      </ns:person>
   </ns:return>
</ns:Response>
</soapenv:Body>
</soapenv:Envelope>

转换后的预期 XML：这是我正在寻找的最终 xml！

<MyResponse>
      <person>
         <personName></personName>
         <personAge></personAge>
         <personAddress>
            <addressType>official</addressType>
            <addressLine1>official address line 1</addressLine1>
         </personAddress>
         <personAddress>
            <addressType>residence</addressType>
            <addressLine1>residence address line 1</addressLine1>
         </personAddress>         
      </person>
</MyResponse>

这是 XSLT，我现在正在使用。但这不会生成我需要的 xml。问题是，如果我不包含模板 match="ns:Response"，则生成的 xml 类似于上面的 xml，除了根标签是“Response”并且它完全符合我的需要。但是当我引入 match="ns:Response" 时，我们的 xml 没有格式化为 xml，并且生成的 xml 在“MyResponse”旁边包含命名空间 xmlns:ns="http://demo.test.classes.com"标签。请让我知道在下面的 xslt 中应该修改什么？

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="xml" indent="yes" />

    <xsl:template match="/|comment()|processing-instruction()">
        <xsl:copy>
            <xsl:apply-templates />
        </xsl:copy>
    </xsl:template>

    <xsl:template match="*">
        <xsl:element name="{local-name()}">
            <xsl:apply-templates select="@*|node()" />
        </xsl:element>
    </xsl:template>

    <xsl:template match="@*">
        <xsl:attribute name="{local-name()}">
      <xsl:value-of select="." />
    </xsl:attribute>
    </xsl:template>

    <xsl:template xmlns:ns="http://demo.test.classes.com" match="ns:return">
    <xsl:apply-templates/>
    </xsl:template>

    <xsl:template xmlns:ns="http://demo.test.classes.com" match="ns:Response">
    <MyResponse><xsl:apply-templates select="node()|@*"/></MyResponse>
    </xsl:template>

</xsl:stylesheet>
4

2 回答 2

1

这种转变：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
 xmlns:x="http://demo.test.classes.com" exclude-result-prefixes="x">
 <xsl:output omit-xml-declaration="yes" indent="yes"/>
 <xsl:strip-space elements="*"/>

 <xsl:template match="x:Response">
  <MyResponse>
   <xsl:apply-templates/>
  </MyResponse>
 </xsl:template>

 <xsl:template match="x:Response/*//*">
  <xsl:element name="{local-name()}">
   <xsl:apply-templates/>
  </xsl:element>
 </xsl:template>
</xsl:stylesheet>

应用于提供的 XML 文档时：

<soapenv:Envelope xmlns:soapenv="http://www.w3.org/2003/05/soap-envelope">
<soapenv:Body>
<ns:Response xmlns:ns="http://demo.test.classes.com">
   <ns:return>
      <ns:person>
         <ns:personName></ns:personName>
         <ns:personAge></ns:personAge>
         <ns:personAddress>
            <ns:addressType>official</ns:addressType>
            <ns:addressLine1>official address line 1</ns:addressLine1>
         </ns:personAddress>
         <ns:personAddress>
            <ns:addressType>residence</ns:addressType>
            <ns:addressLine1>residence address line 1</ns:addressLine1>
         </ns:personAddress>
      </ns:person>
   </ns:return>
</ns:Response>
</soapenv:Body>
</soapenv:Envelope>

产生想要的正确结果：

<MyResponse>
    <person>
        <personName/>
        <personAge/>
        <personAddress>
            <addressType>official</addressType>
            <addressLine1>official address line 1</addressLine1>
        </personAddress>
        <personAddress>
            <addressType>residence</addressType>
            <addressLine1>residence address line 1</addressLine1>
        </personAddress>
    </person>
</MyResponse>
于 2012-09-03T18:21:35.567 回答
0

这是另一个。这是对我对您第一个问题的回答的调整。它比 Dimitre 的更冗长（3 个模板而不是 2 个），但作为补偿它可能更有效，因为匹配条件非常简单。

<xsl:stylesheet version="1.0"
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
    xmlns:soapenv="http://www.w3.org/2003/05/soap-envelope"
    xmlns:ns="http://demo.test.classes.com"
    exclude-result-prefixes="xsl soapenv ns">
<xsl:output method="xml" indent="yes" />
<xsl:strip-space elements="*" />

<xsl:template match="*">
 <xsl:element name="{local-name()}">
  <xsl:apply-templates />
 </xsl:element>
</xsl:template>

<xsl:template match="ns:return">
  <MyResponse>
   <xsl:apply-templates/>
  </MyResponse>
</xsl:template>

<xsl:template match="soapenv:Envelope|soapenv:Body">
  <xsl:apply-templates/>
</xsl:template>

</xsl:stylesheet>
于 2012-09-04T00:14:02.540 回答