php - 使用 xslt 获取属性节点并打印不同的值

Question

<page>
  <tab dim="70"></tab>
  <tab dim="40"></tab>
  <tab dim="30"></tab>
  <tab dim="30"></tab>
  <tab dim="30"></tab>
  <tab dim="70"></tab>
</page>

如何获取选项卡的昏暗属性的值并使用 xslt 取出不同的值。意味着它将打印 30,40,70

Answer 1

要选择不同的属性值，可以使用此 XPath：

/page/tab[not(@dim=preceding-sibling::tab/@dim)]/@dim

一个可能的 XSLT 模板是

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
    <xsl:output method="text" />
    <xsl:template match="/">
        <xsl:for-each select="/page/tab[not(@dim=preceding-sibling::tab/@dim)]/@dim">
            <xsl:sort select="." data-type="number"/>
            <xsl:value-of select="concat(., substring(',', 2 - (position() != last())))"/>
        </xsl:for-each>
    </xsl:template>
</xsl:stylesheet>

要使用PHP 中的样式表转换源文档，您可以使用：

$xml = new DOMDocument;
$xml->load('collection.xml');
$xsl = new DOMDocument;
$xsl->load('collection.xsl');
$proc = new XSLTProcessor;
$proc->importStyleSheet($xsl);
echo $proc->transformToXML($xml);

这将在输出中给出 30,40,70。

您可以在没有 XSLT 的情况下实现同样的效果，只需执行以下操作：

$page = simplexml_load_file('NewFile.xml');
$dims = $page->xpath('/page/tab[not(@dim=preceding-sibling::tab/@dim)]/@dim');
$dims = array_map('strval', $dims);
sort($dims);
echo implode(',', $dims);

另见

• http://schlitt.info/opensource/blog/0704_xpath.html
• 如何使用 XSLT/XPath 生成逗号分隔的列表？
• XPath 1.0 选择兄弟姐妹的不同属性

Answer 2

使用分组preceding-sibling::someName是出了名的慢（O(N^2) -- 二次），并且可能禁止在大型节点集上使用。

这是一个简单且最有效的Muenchian 分组解决方案：

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
 <xsl:output method="text"/>
 <xsl:key name="kTabByDim" match="tab" use="@dim"/>

 <xsl:template match="/*">
  <xsl:apply-templates select=
   "tab[generate-id()=generate-id(key('kTabByDim',@dim)[1])]">
    <xsl:sort select="@dim" data-type="number"/>
  </xsl:apply-templates>
 </xsl:template>
 <xsl:template match="tab">
   <xsl:if test="position() >1">,</xsl:if>
   <xsl:value-of select="@dim"/>
 </xsl:template>
</xsl:stylesheet>

当此转换应用于提供的 XML 文档时：

<page>
  <tab dim="70"></tab>
  <tab dim="40"></tab>
  <tab dim="30"></tab>
  <tab dim="30"></tab>
  <tab dim="30"></tab>
  <tab dim="70"></tab>
</page>

产生了想要的正确结果：

30,40,70