perl - 当我想打印到哈希键中的句柄时，为什么会出现语法错误？

Question

我有代码将当前目录中文件的所有文件句柄存储为哈希值。键是文件的名称。

my %files_list;    #this is a global variable.
sub create_hash() {
    opendir my $dir, "." or die "Cannot open directory: $!";
    my @files = readdir $dir;
    foreach (@files) {
        if (/.text/) {
            open(PLOT, ">>$_") || die("This file will not open!");
            $files_list{$_} = *PLOT;
        }
    }
}

在我面临一些编译问题的代码中，我正在使用打印语句。

my $domain = $_;
opendir my $dir, "." or die "Cannot open directory: $!";
my @files = readdir $dir;
foreach (@files) {
    if (/.text/ && /$subnetwork2/) {
        print $files_list{$_} "$domain";    #this is line 72 where there is error.
    }
}
closedir $dir;

编译错误如下：

String found where operator expected at process.pl line 72, near "} "$domain""
        (Missing operator before  "$domain"?)
syntax error at process.pl line 72, near "} "$domain""

谁能帮我理解错误？

Answer 1

第一个问题：运行create_hash子程序后，您将%files_list填满*PLOT所有键。

全部print {$files_list{$_}} "$domain";打印到最后打开的文件中。
解决方案：

-open(PLOT,">>$_") || die("This file will not open!");
-$files_list{$_}=*PLOT;
+open($files_list{$_},">>$_") || die("This file will not open!");

第二个问题：在打印到文件描述符之前，您没有检查文件描述符是否存在
解决方案：

-if(/.text/ && /$subnetwork2/)
-{
-    print $files_list{$_} "$domain";#this is line 72 where there is error.
+if(/.text/ && /$subnetwork2/ && exists $files_list{$_})
+{
+    print {$files_list{$_}} $domain;

并且不要忘记关闭文件句柄...

Answer 2

也许您应该阅读print 的文档。最后一段说：

如果您将句柄存储在数组或散列中，或者通常每当您使用比裸字句柄或普通的、未下标的标量变量更复杂的表达式来检索它时，您将不得不使用返回文件句柄值的块相反，在这种情况下不能省略 LIST：

print { $files[$i] } "stuff\n";
print { $OK ? STDOUT : STDERR } "stuff\n";

Answer 3

也许是这样的：

print {$files_list{$_}} "$domain";